Arduino環境でLCDモジュールを使う(ILI9486)

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
Raspberry Pi Pico

【スケッチの説明】
LCDのテスト表示を行います。

【ライブラリ】
Raspberry Pi Pico/RP2040 > Raspberry Pi Pico

Adafruit GFX Library
Adafruit ILI9486

【準備】
Raspberry Pi Pico     <-> ILI9486
3.3V                  <-> VCC
GND                   <-> GND
GPIO17(SPI0 CS)       <-> TFT CS
GPIO22                <-> TFT Reset
GPIO28                <-> TFT AO(D/C)
GPIO19(SPI0 MOSI)     <-> TFT SDA
GPIO18(SPI0 SCK)      <-> TFT SCK
3.3V                  <-> LED

【バージョン情報】
2023/2/14 : 新規
**********************************************************************/
#include <SPI.h>
#include <ILI9486_SPI.h>
#include <Adafruit_GFX.h>

//TFT SPIピン設定
#define TFT_CS        17
#define TFT_RST       22
#define TFT_DC        28
#define TFT_MOSI      19
#define TFT_SCK       18

#define ILI9486_BLACK     0x0000
#define ILI9486_WHITE     0xFFFF
#define ILI9486_RED       0xF800
#define ILI9486_GREEN     0x07E0
#define ILI9486_BLUE      0x001F
#define ILI9486_CYAN      0x07FF
#define ILI9486_MAGENTA   0xF81F
#define ILI9486_YELLOW    0xFFE0
#define ILI9486_ORANGE    0xFC00

ILI9486_SPI tft(TFT_CS, TFT_DC, TFT_RST);

void setup(void)
{
  //SPIピン設定
  SPI.setTX(TFT_MOSI);
  SPI.setSCK(TFT_SCK);

  //TFTの初期化と初期設定
  tft.setSpiKludge(false);              // false to disable rpi_spi16_mode
  tft.init();                           //Init ILI9486初期化  
  tft.fillScreen(ILI9486_BLACK);        //背景の塗りつぶし

  //テキスト表示
  tft.setRotation(3);                         //画面回転
  tft.setTextSize(7);                         //サイズ

  tft.setCursor(0, 10);                       //カーソル位置                      
  tft.setTextColor(ILI9486_GREEN);             //緑
  tft.printf("TAMANEGI\n\n");

  tft.setTextSize(4);                         //サイズ
  tft.setTextColor(ILI9486_RED);               //赤
  tft.printf("4.0inch LCD\n");
  tft.setTextColor(ILI9486_YELLOW);            //黄
  tft.printf("Res=480 x 320\n");
  tft.setTextColor(ILI9486_BLUE);              //青
  tft.printf("ILI9486\n");
}

void loop(void)
{

}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
Banana Pi PicoW

【スケッチの説明】
LCDのテスト表示を行います。

【ライブラリ】
esp32 > ESP32S3 Dev Module

Adafruit GFX Library
Adafruit ILI9486

【準備】
Raspberry Pi Pico     <-> ILI9486
3.3V                  <-> VCC
GND                   <-> GND
GPIO2                 <-> TFT CS
GPIO7                 <-> TFT Reset
GPIO10                <-> TFT AO(D/C)
GPIO4                 <-> TFT SDA
GPIO3                 <-> TFT SCK
3.3V                  <-> LED

【バージョン情報】
2023/2/27 : 新規
**********************************************************************/
#include <SPI.h>
#include <ILI9486_SPI.h>
#include <Adafruit_GFX.h>

#define TFT_CS    2
#define TFT_RST   7
#define TFT_DC    10
#define TFT_MOSI  4
#define TFT_SCK   3

#define ILI9486_BLACK     0x0000
#define ILI9486_WHITE     0xFFFF
#define ILI9486_RED       0xF800
#define ILI9486_GREEN     0x07E0
#define ILI9486_BLUE      0x001F
#define ILI9486_CYAN      0x07FF
#define ILI9486_MAGENTA   0xF81F
#define ILI9486_YELLOW    0xFFE0
#define ILI9486_ORANGE    0xFC00

ILI9486_SPI tft(TFT_CS, TFT_DC, TFT_RST);

void setup(void)
{
  //SPIピン設定
  SPI.begin(TFT_SCK, -1, TFT_MOSI, TFT_CS); 

  //TFTの初期化と初期設定
  tft.setSpiKludge(false);              // false to disable rpi_spi16_mode
  tft.init();

  tft.fillScreen(ILI9486_BLACK);        //背景の塗りつぶし

  //テキスト表示
  tft.setRotation(3);                         //画面回転
  tft.setTextSize(7);                         //サイズ

  tft.setCursor(0, 10);                       //カーソル位置                      
  tft.setTextColor(ILI9486_GREEN);             //緑
  tft.printf("TAMANEGI\n\n");

  tft.setTextSize(4);                         //サイズ
  tft.setTextColor(ILI9486_RED);               //赤
  tft.printf("4.0inch LCD\n");
  tft.setTextColor(ILI9486_YELLOW);            //黄
  tft.printf("Res=480 x 320\n");
  tft.setTextColor(ILI9486_BLUE);              //青
  tft.printf("ILI9486\n");
}

void loop(void)
{
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
Raspberry Pi Pico

【スケッチの説明】
タッチパネルを使用し、タッチ位置をLCD画面に表示します。

【ライブラリ】
Raspberry Pi Pico/RP2040 > Raspberry Pi Pico

Adafruit GFX Library
Adafruit ILI9486
XPT2046_Touchscreen

【準備】
<<LCD側>>
Raspberry Pi Pico     <-> ILI9486
3.3V                  <-> VCC
GND                   <-> GND
GPIO17(SPI0 CS)       <-> TFT CS
GPIO22                <-> TFT Reset
GPIO28                <-> TFT AO(D/C)
GPIO19(SPI0 MOSI)     <-> TFT SDA
GPIO18(SPI0 SCK)      <-> TFT SCK
3.3V                  <-> LED

<<Touch側>>
GPIO20                <-> T_CS
GPIO16(SPI0 MISO)     <-> T_OUT(MISO)
GPIO18(SPI0 SCK)      <-> T_CLK
GPIO19(SPI0 MOSI)     <-> T_DIN(MOSI)

【バージョン情報】
2023/2/14 : 新規
**********************************************************************/

#include <SPI.h>
#include <ILI9486_SPI.h>
#include <Adafruit_GFX.h>
#include <XPT2046_Touchscreen.h>

//TFT SPIピン設定
#define TFT_CS        17
#define TFT_RST       22
#define TFT_DC        28
#define TFT_MOSI      19
#define TFT_SCK       18

#define ILI9486_BLACK     0x0000
#define ILI9486_WHITE     0xFFFF
#define ILI9486_RED       0xF800
#define ILI9486_GREEN     0x07E0
#define ILI9486_BLUE      0x001F
#define ILI9486_CYAN      0x07FF
#define ILI9486_MAGENTA   0xF81F
#define ILI9486_YELLOW    0xFFE0
#define ILI9486_ORANGE    0xFC00

#define COMMON_SCK  18
#define COMMON_MOSI 19
#define COMMON_MISO 16

#define TOUCH_CS 20

XPT2046_Touchscreen ts(TOUCH_CS);
ILI9486_SPI tft(TFT_CS, TFT_DC, TFT_RST);

void setup()
{
  Serial.begin(115200);

  //ESP SPI ピン設定
  SPI.setTX(COMMON_MOSI);
  SPI.setRX(COMMON_MISO);
  SPI.setSCK(COMMON_SCK);

  //TFTの初期化と初期設定
  tft.setSpiKludge(false);              // false to disable rpi_spi16_mode
  tft.init();                           //Init ILI9486初期化  
  tft.fillScreen(ILI9486_BLACK);        //背景の塗りつぶし
  tft.setRotation(3);
  tft.setTextSize(2);
  tft.fillScreen(ILI9486_BLACK);

  //タッチ入力開始
  ts.begin();
  ts.setRotation(1);

}

void loop()
{
  //タッチ状態読み取り
  boolean bTouch = ts.touched();
  //画面クリア
  tft.fillRect(0, 0, 640, 100, ILI9486_BLACK);

  //タッチがあればタッチされている座標の表示
  if (bTouch == true)
  {
   TS_Point tPoint = ts.getPoint();
    tft.setTextColor(ILI9486_WHITE);
    tft.setCursor(0, 0);
    tft.printf("(x,y) = (%d, %d)\r\n", tPoint.x, tPoint.y);
    Serial.printf("(x,y) = (%d, %d)\r\n", tPoint.x, tPoint.y);
  }
  else 
  {
    //タッチがなければタッチ無表示
    tft.setTextColor(ILI9486_RED);
    tft.setCursor(0, 0);
    tft.print("No Touch");
    
  }
  delay(200);
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
Raspberry Pi Pico

【スケッチの説明】
SDカードモジュールからtest.jpgを読み出しILI9486に表示します。

【ライブラリ】
Raspberry Pi Pico/RP2040 > Raspberry Pi Pico

Adafruit GFX Library
Adafruit ILI9486
TJpg_Decoder

【準備】
SDカードのルートフォルダに "test.jpg"を保存します。
jpgファイルのサイズは 480 x 320 サイズで保存します。

SPI0のMOSIとSCKは共通で使用します。
ILI9486に実装されているSDカードリーダ以外のモジュールを使用する場合、電源とGNDを配線します。

<<TFT側>>
Raspberry Pi Pico     <-> ILI9486
3.3V                  <-> VCC
GND                   <-> GND
GPIO17(SPI0 CS)       <-> TFT CS
GPIO22                <-> TFT Reset
GPIO28                <-> TFT AO(D/C)
GPIO19(SPI0 MOSI)     <-> TFT SDA
GPIO18(SPI0 SCK)      <-> TFT SCK
3.3V                  <-> LED

<<SDカードリーダ側>>
Raspberry Pi Pico     <-> TFカードリーダ
3.3V                  <-> VCC
GND                   <-> GND
GPIO21                <-> SD CS
GPIO19(SPI0 MOSI)     <-> SD MOSI
GPIO16(SPI0 MISO)     <-> SD MISO
GPIO18(SPI0 SCK)      <-> SD SCK

【バージョン情報】
2023/2/14 : 新規
**********************************************************************/

#include <SPI.h>
#include <SD.h>

#include <TJpg_Decoder.h>
#include <ILI9486_SPI.h>
#include <Adafruit_GFX.h>

//TFT SD共通ピン設定
#define COMMON_MOSI   19
#define COMMON_SCK    18

//TFTピン設定
#define TFT_CS        17
#define TFT_RST       22
#define TFT_DC        28

//SDピン設定
#define SD_CS         21  
#define SD_MISO       16
#define FILENAME      "/test.jpg"

#define BLACK   0x0000      //パレット 黒
#define WHITE   0xFFFF      //パレット 白

// JPGの最大サイズ(バッファを静的に確保するようにしているため、決め打ち。取り扱う最大ファイルサイズで変えるようにする)
#define JPG_SIZE_MAX (100 * 1024) //MAX 100KByteを想定

ILI9486_SPI tft(TFT_CS, TFT_DC, TFT_RST);

struct jpg_file
{
  size_t size;
  uint8_t buf[JPG_SIZE_MAX];
};

jpg_file jpg;

//デコードを行うコールバック関数
bool tft_output(int16_t x, int16_t y, uint16_t w, uint16_t h, uint16_t *bitmap)
{
  if (y >= tft.height())
    return 0;

  tft.drawRGBBitmap(x, y, bitmap, w, h);

  return 1;
}

void setup()
{
  //SPIピン設定
  SPI.setTX(COMMON_MOSI);
  SPI.setRX(SD_MISO);
  SPI.setSCK(COMMON_SCK);

  //TFTの初期化と初期設定
  tft.setSpiKludge(false);      // false to disable rpi_spi16_mode
  tft.init();                   //Init ILI9486初期化  
  tft.fillScreen(BLACK);        //背景の塗りつぶし
  tft.setRotation(3);

  Serial.begin(115200);
  //while(!Serial);
  delay(1000);
  
  //SDカードリーダの初期化とファイルの読み取り
  if (!SD.begin(SD_CS, SD_SCK_MHZ(8)))
  {
    Serial.println("SD initialization failed!");
    while(1);
  }

  TJpgDec.setCallback(tft_output);

  File jpgFile = SD.open(FILENAME, FILE_READ);
  if (!jpgFile)
  {
    Serial.printf("Open file failed [%s]\r\n", FILENAME);
    while(1);
  }

  jpg.size = jpgFile.size();

  if(sizeof(jpg.buf) < jpg.size) 
  {
    Serial.println("File size over");
    return;
  }

  //ファイル情報の表示
  uint16_t w = 0, h = 0;
  Serial.printf("file size = %d bytes\r\n", jpgFile.readBytes((char *)jpg.buf, jpg.size));
  TJpgDec.getJpgSize(&w, &h, jpg.buf, jpg.size);
  Serial.printf("Width = %d, height = %d\r\n", w, h);

  TJpgDec.setJpgScale(1);
  TJpgDec.drawJpg(0, 0, jpg.buf, jpg.size);             //画像の表示

  jpgFile.close();
}

void loop()
{
}