Arduino環境でSDカードモジュールを使う

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【スケッチの説明】
SDカードにsample.txtに追記保存します。

ファイルにCOMから入力の有った文字列を書き込みます。

【ライブラリ】
不要

【準備】
YD RP2040     SD Card Module
GND       <-> GND
Vout      <-> VCC
GP16      <-> MISO
GP19      <-> MOSI
GP18      <-> SCK
GP17      <-> CS

【参考】
'http://www.musashinodenpa.com/arduino/ref/index.php

【バージョン情報】
2022/9/21 : 新規
**********************************************************************/

#include <SPI.h>
#include <SD.h>

//SPI0 を使用するためのピン番号定義
#define SD_MOSI 19
#define SD_SCK  18
#define SD_CS   17
#define SD_MISO 16

#define FILENAME "sample.txt" //保存ファイル名
File myFile;                  //ファイル操作オブジェクト

void setup()
{

  Serial.begin(115200);       //COMオープン。今回ここから入力の有った文字をファイルに保存します。

  SPI.setTX(SD_MOSI);         //RP2040系　SPI0 ピン設定
  SPI.setSCK(SD_SCK);
  SPI.setRX(SD_MISO);
  SPI.setCS(SD_CS);

  //SPIを指定ピンにするために、CSとSPIオブジェクトを使用するオーバーライド関数を使用する。
  if (SD.begin(SD_CS, SPI) == false)
  {
    Serial.println("initialization failed.");   //SDカードモジュールの初期化に失敗したらポーリング
    while (1);
  }

  myFile = SD.open(FILENAME, FILE_WRITE);       //追記モードでオープン
}

void loop()
{
  char buf = 0;

  //COMに入力があったか : 0 = なし / else = 入力あり
  if(Serial.available() != 0)
  {
    buf = Serial.read();                   
  
    if(buf == 0x1a)                             //入力コードが 0x1a(CTRL + z)の場合
    {
        myFile.close();                         //終了コードの場合ファイルを閉じてポーリングする。
        Serial.printf("Closed file.");
        while(1);
    }

    //終了コードではない場合、ファイルへ保存する。
    myFile.printf("%c", buf);
  }
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【スケッチの説明】
SDカードのsample.txtがあれば読み取りを開始します。
読み取ったデータをCOMに送信します。
すべて読み取った後に、"--EOF--"をCOMに送信します。

【ライブラリ】
不要

【準備】
YD RP2040     SD Card Module
GND       <-> GND
Vout      <-> VCC
GP16      <-> MISO
GP19      <-> MOSI
GP18      <-> SCK
GP17      <-> CS

【参考】
'http://www.musashinodenpa.com/arduino/ref/index.php

【バージョン情報】
2022/9/21 : 新規
**********************************************************************/

#include <SPI.h>
#include <SD.h>

//SPI0 を使用するためのピン番号定義
#define SD_MOSI 19
#define SD_SCK  18
#define SD_CS   17
#define SD_MISO 16

#define FILENAME "sample.txt" //保存ファイル名
File myFile;                  //ファイル操作オブジェクト

void setup()
{
  delay(500);                 //ウエイトを入れてから起動しないとシリアルが出力されない。

  Serial.begin(115200);       //COMオープン。今回ここから入力の有った文字をファイルに保存します。

  SPI.setTX(SD_MOSI);         //RP2040系　SPI0 ピン設定
  SPI.setSCK(SD_SCK);
  SPI.setRX(SD_MISO);
  SPI.setCS(SD_CS);

  //SPIを指定ピンにするために、CSとSPIオブジェクトを使用するオーバーライド関数を使用する。
  if (SD.begin(SD_CS, SPI) == false)
  {
    Serial.println("initialization failed.");   //SDカードモジュールの初期化に失敗したらポーリング
    while (1);
  }

  //読み取りモードでファイルを開く
  myFile = SD.open(FILENAME, FILE_READ);
  if (myFile == false) 
  {
    Serial.println("open file failed.");
    while(1);
  }

  char buf = 0;

  //ファイルにデータがなくなるまで繰り返す
  while (myFile.available() != 0)
  {
    buf = myFile.read();
    
    //読みだしたテキストファイルの改行コード(0x0d)では、Teraterm上では先頭移動になるだけで
    //以前の読み出した文字が上書きされてしまうため、次の行へ移動させる処理
    if(buf == 0x0d)Serial.println("");        
    
    Serial.write(buf);              //読み取ったデータをCOMに出力
  }
  myFile.close();                             //ファイルを閉じる
  Serial.println("");
  Serial.println("--EOF--\n");

}

void loop()
{
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【スケッチの説明】
SDカードにsample.txtの存在を確認します。
存在すれば削除します。

【ライブラリ】
不要

【準備】
YD RP2040     SD Card Module
GND       <-> GND
Vout      <-> VCC
GP16      <-> MISO
GP19      <-> MOSI
GP18      <-> SCK
GP17      <-> CS

【参考】
'http://www.musashinodenpa.com/arduino/ref/index.php

【バージョン情報】
2022/9/23 : 新規
**********************************************************************/
// ライブラリのインクルード
#include <SD.h>     // SD関連
#include <SPI.h>    // SPI関連
 
//SPI0 を使用するためのピン番号定義
#define SD_MOSI 19
#define SD_SCK  18
#define SD_CS   17
#define SD_MISO 16

#define FILENAME "sample.txt" //保存ファイル名
 
void setup()
{
  bool bSDResult = false;

  delay(500);
  Serial.begin(115200);
  Serial.print("");
 
  SPI.setTX(SD_MOSI);         //RP2040系　SPI0 ピン設定
  SPI.setSCK(SD_SCK);
  SPI.setRX(SD_MISO);
  SPI.setCS(SD_CS);
 
  bSDResult = SD.begin(SD_CS, SPI);
  if(bSDResult == true)
  {
    //ファイルの存在確認 : false = 無い / true = 有る
    if(SD.exists(FILENAME) == true)
    {
      SD.remove(FILENAME);      //ファイルの削除
Serial.println("削除成功");
    }
    else                        //ファイルが見つからなかった場合
    {
Serial.println("ファイルが見つかりません");
    }
  }
}
 
void loop()
{
 
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【スケッチの説明】
SDカードの指定したフォルダからファイルとフォルダのサイズとリストを作成します。
ファイルの場合は F, フォルダ(ディレクトリ)の場合は Dを先頭につけます。
続いて見つかった番号、ファイル名、ファイルサイズの順で表示します。

【ライブラリ】
不要

【準備】
YD RP2040     SD Card Module
GND       <-> GND
Vout      <-> VCC
GP16      <-> MISO
GP19      <-> MOSI
GP18      <-> SCK
GP17      <-> CS

【参考】
'http://www.musashinodenpa.com/arduino/ref/index.php

【バージョン情報】
2022/9/21 : 新規
**********************************************************************/


#include <SPI.h>
#include <SD.h>

//SPI0 を使用するためのピン番号定義
#define SD_MOSI 19
#define SD_SCK  18
#define SD_CS   17
#define SD_MISO 16

File tFiles;      //Fileオブジェクト

void setup()
{

  delay(500);
  Serial.begin(115200);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

  SPI.setTX(SD_MOSI);         //RP2040系　SPI0 ピン設定
  SPI.setSCK(SD_SCK);
  SPI.setRX(SD_MISO);
  SPI.setCS(SD_CS);

  //SPIを指定ピンにするために、CSとSPIオブジェクトを使用するオーバーライド関数を使用する。
  if (SD.begin(SD_CS, SPI) == false)
  {
    Serial.println("initialization failed.");   //SDカードモジュールの初期化に失敗したらポーリング
    while (1);
  }
  tFiles = SD.open("/");        //ルートフォルダ(/)のファイルをすべて読み取る。

  File tNewFile;
  int iFileIndex = 1;

  while(1)
  {
    tNewFile = tFiles.openNextFile();      //ルートフォルダの見つかったリストがまだあるか？
    if(tNewFile == 0)break;

    //見つかったリストがファイルなら F, ディレクトリ(フォルダ)ならF を表示
    if(tNewFile.isDirectory() == true)
    {
      Serial.printf("D ");
    }
    else
    {
      Serial.printf("F ");
    }

    //見つかったインデックス、ファイル名、ファイルサイズを表示する
    Serial.printf("%02d : %s : %d\n", iFileIndex, tNewFile.name(), tNewFile.size());        //見つかった番号とファイル名をシリアル出力
    iFileIndex ++;
  }

  tNewFile.close();
  tFiles.close();

}

void loop()
{
}