RaspberryPi Picoで感圧式タッチ付きLCDモジュールを使う(ST7735)

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RaspberryPi Pico 

【スケッチの説明】
ST7735 LCDの制御をします。
SPIは SPI0とSPI1のどちらのサンプルも掲載しますが、
SPI1側はコメントアウトしますので、状況に応じてコメントを外してください。
※コメント検索 [SPI1の場合]

【ライブラリ】
Raspberry Pi Pico / RP2040 > Raspberry Pi Pico
Adafruit ST7735 and ST7789 Library (修正版)
Adafruit GFX Library

【準備】
マイコン基板 <-> ST7735
3V3               <-> VCC
GND               <-> GND
GPIO1(SPI0 CS)    <-> CS
GPIO28            <-> Reset
GPIO27            <-> AO
GPIO3(SPI0 MOSI)  <-> SDA
GPIO2(SPI0 SCK)   <-> SCK

【バージョン情報】
2023/6/1 : 新規
**********************************************************************/

#include <Adafruit_GFX.h> 
#include <Adafruit_ST7735.h>
#include <SPI.h>

//SPI0の場合
#define TFT_CS          1   // CS
#define TFT_RST         28  // Reset 
#define TFT_DC          27  // DC
#define TFT_MOSI        3   // MOSI
#define TFT_SCK         2   // SCK

//SPI1の場合
// #define TFT_CS          13  // CS
// #define TFT_RST         28  // Reset 
// #define TFT_DC          27  // DC
// #define TFT_MOSI        15  // MOSI
// #define TFT_SCK         14  // SCK

//SPI0の場合
Adafruit_ST7735 tft = Adafruit_ST7735(&SPI, TFT_CS, TFT_DC, TFT_RST);
//SPI1の場合
//Adafruit_ST7735 tft = Adafruit_ST7735(&SPI1, TFT_CS, TFT_DC, TFT_RST);

void setup(void) 
{
  //SPI0の場合
  SPI.setTX(TFT_MOSI);
  SPI.setSCK(TFT_SCK);

  //SPI1の場合
  // SPI1.setTX(TFT_MOSI);
  // SPI1.setSCK(TFT_SCK);
  

  tft.initR(INITR_BLACKTAB2);                  //Init ST7735S初期化 修正版ライブラリ使用
//  tft.initR(INITR_BLACKTAB);                  //Init ST7735S初期化 修正版ライブラリを使用しない場合は表示ずれがあるが、こちらで初期化

  tft.fillScreen(ST77XX_BLACK);               //背景の塗りつぶし

    //テキスト表示
  tft.setRotation(3);                         //画面回転
  tft.setTextSize(3);                         //サイズ

  tft.setCursor(0, 10);                       //カーソル位置                      
  tft.setTextColor(ST77XX_GREEN);             //緑
  tft.printf("TAMANEGI\n");

  tft.setCursor(0, 50);                       //カーソル位置                      
  tft.setTextSize(2);                         //サイズ
  tft.setTextColor(ST77XX_RED);               //赤
  tft.printf("1.8inch LCD\n");
  tft.setTextColor(ST77XX_YELLOW);            //黄
  tft.printf("Res=128 x 160\n");
  tft.setTextColor(ST77XX_BLUE);              //青
  tft.printf("ST7735\n");
}

void loop()
{
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RaspberryPi Pico 

【スケッチの説明】
ST7735 LCDの制御をします。

【ライブラリ】
Raspberry Pi Pico / RP2040 > Raspberry Pi Pico
Adafruit ST7735 and ST7789 Library (修正版)
Adafruit GFX Library

【準備】
マイコン基板 <-> ST7735
3V3               <-> VCC
GND               <-> GND
GPIO12(SPI CS)    <-> CS
GPIO9             <-> Reset
GPIO8             <-> AO
GPIO14(SPI MOSI)  <-> SDA
GPIO13(SPI SCK)   <-> SCK
GPIO15(SPI MISO)  <-> non   ピン番号の変更だけ

【バージョン情報】
2023/6/1 : 新規
**********************************************************************/

#include <Adafruit_GFX.h> 
#include <Adafruit_ST7735.h>
#include <SPI.h>

//SPI0の場合
#define TFT_CS          12    // CS
#define TFT_RST         9     // Reset 
#define TFT_DC          8     // DC
#define TFT_MOSI        14    // MOSI
#define TFT_SCK         13    // SCK
#define TFT_MISO        15    //MISO      //表示では使用しませんが、デフォルトMISO位置に別のSPI機能を設定すると動作しなくなるためMISO位置を変更する


//VSPIの場合
Adafruit_ST7735 tft = Adafruit_ST7735(&SPI, TFT_CS, TFT_DC, TFT_RST);

void setup(void) 
{
  SPI.begin(TFT_SCK, TFT_MISO, TFT_MOSI, TFT_CS); 


  tft.initR(INITR_BLACKTAB2);                  //Init ST7735S初期化 修正版ライブラリ使用
//  tft.initR(INITR_BLACKTAB);                  //Init ST7735S初期化 修正版ライブラリを使用しない場合は表示ずれがあるが、こちらで初期化

  tft.fillScreen(ST77XX_BLACK);               //背景の塗りつぶし

    //テキスト表示
  tft.setRotation(3);                         //画面回転
  tft.setTextSize(3);                         //サイズ

  tft.setCursor(0, 10);                       //カーソル位置                      
  tft.setTextColor(ST77XX_GREEN);             //緑
  tft.printf("TAMANEGI\n");

  tft.setCursor(0, 50);                       //カーソル位置                      
  tft.setTextSize(2);                         //サイズ
  tft.setTextColor(ST77XX_RED);               //赤
  tft.printf("1.8inch LCD\n");
  tft.setTextColor(ST77XX_YELLOW);            //黄
  tft.printf("Res=128 x 160\n");
  tft.setTextColor(ST77XX_BLUE);              //青
  tft.printf("ST7735\n");
}

void loop()
{
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
Raspberry Pi Pico

【スケッチの説明】
タッチパネルを使用し、タッチ位置をLCD画面に表示します。

【ライブラリ】
Raspberry Pi Pico / RP2040 > Raspberry Pi Pico
Adafruit ST7735 and ST7789 Library (修正版)
Adafruit GFX Library
XPT2046_Touchscreen

【準備】
<<LCD側>>
Raspberry Pi Pico     <-> ST7735
3.3V                  <-> VCC
GND                   <-> GND
GPIO1(SPI0 CS)        <-> TFT CS
GPIO28                <-> TFT Reset
GPIO27                <-> TFT AO(D/C)
GPIO3(SPI0 MOSI)      <-> TFT SDA
GPIO2(SPI0 SCK)       <-> TFT SCK
3.3V                  <-> LED

<<Touch側>>
GPIO5                 <-> T_CS
GPIO0(SPI0 MISO)      <-> T_DO(MISO)
GPIO2(SPI0 SCK)       <-> T_CLK
GPIO3(SPI0 MOSI)      <-> T_DIN(MOSI)

【バージョン情報】
2023/6/1 : 新規
**********************************************************************/

#include <SPI.h>
#include <Adafruit_ST7735.h>
#include <Adafruit_GFX.h>
#include <XPT2046_Touchscreen.h>

//TFT SPIピン設定
#define TFT_CS          1   // CS
#define TFT_RST         28  // Reset 
#define TFT_DC          27  // DC
#define TFT_MOSI        3   // MOSI
#define TFT_SCK         2   // SCK

#define COMMON_SCK  2
#define COMMON_MOSI 3
#define COMMON_MISO 0

#define TOUCH_CS 5

XPT2046_Touchscreen ts(TOUCH_CS);
Adafruit_ST7735 tft = Adafruit_ST7735(&SPI, TFT_CS, TFT_DC, TFT_RST);

void setup()
{
  Serial.begin(115200);

  //SPI ピン設定
  SPI.setTX(COMMON_MOSI);
  SPI.setRX(COMMON_MISO);
  SPI.setSCK(COMMON_SCK);

  //TFTの初期化と初期設定
  tft.initR(INITR_BLACKTAB2);          //Init ST7735S初期化 修正版ライブラリ使用

  tft.fillScreen(ST77XX_BLACK);        //背景の塗りつぶし
  tft.setRotation(3);
  tft.setTextSize(1);
  tft.fillScreen(ST77XX_BLACK);

  //タッチ入力開始
  ts.begin();
  ts.setRotation(1);

}

void loop()
{
  //タッチ状態読み取り
  boolean bTouch = ts.touched();
  //画面クリア
  tft.fillRect(0, 0, 128, 64, ST77XX_BLACK);

  //タッチがあればタッチされている座標の表示
  if (bTouch == true)
  {
   TS_Point tPoint = ts.getPoint();
    tft.setTextColor(ST77XX_WHITE);
    tft.setCursor(0, 0);
    tft.printf("(x,y) = (%d, %d)\r\n", tPoint.x, tPoint.y);
    Serial.printf("(x,y) = (%d, %d)\r\n", tPoint.x, tPoint.y);
  }
  else 
  {
    //タッチがなければタッチ無表示
    tft.setTextColor(ST77XX_RED);
    tft.setCursor(0, 0);
    tft.print("No Touch");
    
  }
  delay(10);
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
Raspberry Pi Pico

【スケッチの説明】
SDカードモジュールからtest.jpgを読み出しST7735に表示します。

【ライブラリ】
Raspberry Pi Pico/RP2040 > Raspberry Pi Pico

Adafruit GFX Library
Adafruit ST7735 and ST7789 Library (修正版)
TJpg_Decoder

【準備】
SDカードのルートフォルダに "test.jpg"を保存します。
jpgファイルのサイズは 160 x 128 サイズで保存します。

SPI0のMOSIとSCKは共通で使用します。
Raspberry Pi Pico     <-> ST7735
<<TFT側>>
3.3V                  <-> VCC
GND                   <-> GND
GPIO1(SPI0 CS)        <-> TFT CS
GPIO28                <-> TFT Reset
GPIO27                <-> TFT AO(D/C)
GPIO3(SPI0 MOSI)      <-> TFT SDA
GPIO2(SPI0 SCK)       <-> TFT SCK
3.3V                  <-> LED

<<SDカードリーダ側>>
GPIO6                 <-> SD CS
GPIO3(SPI0 MOSI)      <-> SD MOSI
GPIO0(SPI0 MISO)      <-> SD MISO
GPIO2(SPI0 SCK)       <-> SD SCK

【バージョン情報】
2023/6/1 : 新規
**********************************************************************/

#include <SPI.h>
#include <SD.h>

#include <TJpg_Decoder.h>
#include <Adafruit_ST7735.h>
#include <Adafruit_GFX.h>

#define TFT_CS          1   // CS
#define TFT_RST         28  // Reset 
#define TFT_DC          27  // DC
#define TFT_MOSI        3   // MOSI
#define TFT_SCK         2   // SCK

#define COMMON_SCK  2
#define COMMON_MOSI 3
#define COMMON_MISO 0

#define SD_CS 6

#define FILENAME      "/test160x128.jpg"

// JPGの最大サイズ(バッファを静的に確保するようにしているため、決め打ち。取り扱う最大ファイルサイズで変えるようにする)
#define JPG_SIZE_MAX (20 * 1024) //MAX 20KByteを想定

Adafruit_ST7735 tft = Adafruit_ST7735(&SPI, TFT_CS, TFT_DC, TFT_RST);     //SPI0を使用

struct jpg_file
{
  size_t size;
  uint8_t buf[JPG_SIZE_MAX];
};

jpg_file jpg;

//デコードを行うコールバック関数
bool tft_output(int16_t x, int16_t y, uint16_t w, uint16_t h, uint16_t *bitmap)
{
  if (y >= tft.height())
    return 0;

  tft.drawRGBBitmap(x, y, bitmap, w, h);

  return 1;
}

void setup()
{
  //SPIピン設定
  SPI.setTX(COMMON_MOSI);
  SPI.setRX(COMMON_MISO);
  SPI.setSCK(COMMON_SCK);

  //TFTの初期化と初期設定
  tft.initR(INITR_BLACKTAB2);                  //Init ST7735S初期化  (修正ライブラリ)
  tft.fillScreen(ST77XX_BLACK);               //背景の塗りつぶし
  tft.setRotation(3);
  
  Serial.begin(115200);
  //while(!Serial);
  delay(1000);
  
  //SDカードリーダの初期化とファイルの読み取り
  if (!SD.begin(SD_CS, SD_SCK_MHZ(16)))
  {
    Serial.println("SD initialization failed!");
    while(1);
  }

  TJpgDec.setCallback(tft_output);

  File jpgFile = SD.open(FILENAME, FILE_READ);
  if (!jpgFile)
  {
    Serial.printf("Open file failed [%s]\r\n", FILENAME);
    while(1);
  }

  jpg.size = jpgFile.size();

  if(sizeof(jpg.buf) < jpg.size) 
  {
    Serial.println("File size over");
    return;
  }

  //ファイル情報の表示
  uint16_t w = 0, h = 0;
  Serial.printf("file size = %d bytes\r\n", jpgFile.readBytes((char *)jpg.buf, jpg.size));
  TJpgDec.getJpgSize(&w, &h, jpg.buf, jpg.size);
  Serial.printf("Width = %d, height = %d\r\n", w, h);

  TJpgDec.setJpgScale(1);
  TJpgDec.drawJpg(0, 0, jpg.buf, jpg.size);             //画像の表示

  jpgFile.close();
}

void loop()
{
}