Arduino環境でRP2040-Core-Aを使う

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040-Core-A

【スケッチの説明】
タクトボタンとLEDの組み合わせの動作をします。

タクトボタンはPULLDOWN設定します。（押下したらHIGH)
タクトボタンを読み取り、押下されるとLEDが点灯します。
ボタンが離されるとLEDは消灯します。

【ライブラリ】
Raspberry Pi Pico / RP2040 > Generic RP2040

【準備】
3.3V -> タクトボタン -> GPIO7
GPIO6 -> 保護抵抗(200Ω) -> LED -> GND

【バージョン情報】
2023/7/26 : 新規
**********************************************************************/

#define LED 6        //LED用 GPIO番号
#define BUTTON 7    //タクトスイッチ

void setup()
{
  pinMode(LED, OUTPUT);               //ピン出力設定
  pinMode(BUTTON, INPUT_PULLDOWN);    //プルダウンで入力
}

void loop()
{
  int iStat = digitalRead(BUTTON);
  digitalWrite(LED, iStat);           //ボタンの状態をLEDに出力
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040-Core-A

【スケッチの説明】
PWM出力でのフェード点灯（ゆっくり点灯）とフェード消灯（ゆっくり消灯）を行います。

【ライブラリ】
Raspberry Pi Pico / RP2040 > Generic RP2040

【準備】
GPIO6 -> 保護抵抗(200Ω) -> LED -> GND

【バージョン情報】
2023/7/26 : 新規
**********************************************************************/
#define PWM 6       //PWM 出力pin

void setup()
{
  pinMode(PWM , OUTPUT);
}

void loop()
{
  for(int i = 0; i < 256; i ++)
  {
    analogWrite(PWM, i);
    delay(2);
  }

  for(int i = 0; i < 256; i ++)
  {
    analogWrite(PWM, 255 - i);
    delay(2);
  }
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040-Core-A

【スケッチの説明】
入力された電圧を読み取ります。

【ライブラリ】
 Raspberry Pi Pico/RP2040 > Generic RP2040

【準備】
マイコン基板 <-> LOLIN32 Lite
GPIO29(ADC)         <-> GPIO26(DAC)
GND                 <-> GND

【バージョン情報】
2023/7/28 : 新規
**********************************************************************/

#define ADC 29

void setup()
{
  Serial.begin(115200);
  pinMode(ADC, INPUT);
}

void loop()
{
  int iADC = 0;

  //外部から入力された電圧を読み取り、結果をCOMに出力します。
  iADC = analogRead(ADC);
  Serial.printf("(ADC) = %d\r\n", iADC);
  delay(2);
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040-Core-A

【スケッチの説明】
COM と UART1の通信をします。

COMから受信した内容をUART1へ送信します。
UART1から受信した内容をCOMへ送信します。

【ライブラリ】
Raspberry Pi Pico/RP2040 > Generic RP2040

【準備】
UART0の送受信にFT232RLを使用します。

RP2040-Core-A <-> FT232RL
GPIO12 (UART1 TX) <-> RX
GP1O29 (UART1 RX) <-> TX

【バージョン情報】
2023/7/28 : 新規
**********************************************************************/

void setup()
{
  //Serial は USB(COM)を使ったシリアル通信用オブジェクト
  //Serial1は UART0の通信オブジェクト
  //Serial2は UART1の通信オブジェクト

  Serial1.setTX(12);                    //UART0はSerial1オブジェクトを使用します。
  Serial1.setRX(29);                    //デフォルトではTX = 0, RX = 1

  Serial.begin(115200);                 //SerialオブジェクトはUART0 (COM)
  Serial1.begin(115200);                //Serial1オブジェクトはUART1
}

void loop()
{
  if(Serial.available() != 0)           //COMにデータがあれば、読み取った内容をUART1に送信
  {
      Serial1.write(Serial.read());
  }

  if(Serial1.available() != 0)           //UART1にデータがあれば、読み取った内容をCOMに送信
  {
      Serial.write(Serial1.read());
  }
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040-Core-A

【スケッチの説明】
SSD1306 OLEDの制御をします。
I2Cは I2C0とI2C1のどちらのサンプルも掲載しますが、
I2C0側はコメントアウトしますので、状況に応じてコメントを外してください。
※コメント検索 [I2C0の場合]

【ライブラリ】
Raspberry Pi Pico / RP2040 > Generic RP2040

【準備】
マイコン基板 <-> SSD1306
3V3             <-> VCC
GND             <-> GND
GPIO6(I2C1 SDA) <-> SDA
GPIO7(I2C1 SCL) <-> SCL

【バージョン情報】
2023/7/28 : 新規
**********************************************************************/

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>


#define PIN_SDA 6
#define PIN_SCL 7

#define SCREEN_WIDTH 128                //解像度 128 x 64 で使用します。
#define SCREEN_HEIGHT 64                //SCREEN_HEIGHTは 32 に設定することができます。

#define OLED_RESET     -1               //使用しないので　-1を設定する。
#define SCREEN_ADDRESS 0x3C             //I2Cアドレスは 0x3C

//Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);     //I2C0の場合
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire1, OLED_RESET);     //I2C1の場合
                                        
void setup()
{
  
  // // //I2C0の場合
  // Wire.setSDA(PIN_SDA);
  // Wire.setSCL(PIN_SCL);

  //I2C1の場合
  Wire1.setSDA(PIN_SDA);
  Wire1.setSCL(PIN_SCL);


  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    for(;;);
  }

  display.clearDisplay();               //何か表示されている場合に備えて表示クリア

  display.setTextSize(2);               //フォントサイズは2(番目に小さい)
  display.setTextColor(SSD1306_WHITE);  //色指定はできないが必要
  display.setCursor(20, 0);            //テキストの表示開始位置
  display.print(F("TAMANEGI"));         //表示文字列
  display.setCursor(15, 25);
  display.print(F("OLED 0.96"));
  display.setCursor(25, 45);
  display.print(F("SSD1306"));

  display.display();                    //バッファ転送（表示)
}

void loop()
{
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040-Core-A

【スケッチの説明】
ST7735 LCDの制御をします。
SPIは SPI0とSPI1のどちらのサンプルも掲載しますが、
SPI0側はコメントアウトしますので、状況に応じてコメントを外してください。
※コメント検索 [SPI0の場合]

【ライブラリ】
Raspberry Pi Pico / RP2040 > Generic RP2040
Adafruit ST7735 and ST7789 Library
Adafruit GFX Library

【準備】
マイコン基板 <-> ST7735
3V3               <-> VCC
GND               <-> GND
GPIO9(SPI1 CS)    <-> CS
GPIO6             <-> Reset
GPIO7             <-> AO
GPIO11(SPI1 MOSI) <-> SDA
GPIO10(SPI1 SCK)  <-> SCK

【バージョン情報】
2023/7/28 : 新規
**********************************************************************/

#include <Adafruit_GFX.h> 
#include <Adafruit_ST7735.h>
#include <SPI.h>

//SPIピン定義
#define TFT_CS          9   // CS
#define TFT_RST         6   // Reset 
#define TFT_DC          7   // DC
#define TFT_MOSI        11  // MOSI
#define TFT_SCK         10  // SCK


//SPI0の場合
//Adafruit_ST7735 tft = Adafruit_ST7735(&SPI, TFT_CS, TFT_DC, TFT_RST);
//SPI1の場合
Adafruit_ST7735 tft = Adafruit_ST7735(&SPI1, TFT_CS, TFT_DC, TFT_RST);

void setup(void) 
{
  // //SPI0の場合
  // SPI.setTX(TFT_MOSI);
  // SPI.setSCK(TFT_SCK);

  //SPI1の場合
  SPI1.setTX(TFT_MOSI);
  SPI1.setSCK(TFT_SCK);
  

  tft.initR(INITR_BLACKTAB);                  //Init ST7735S初期化
  
  tft.fillScreen(ST77XX_BLACK);               //背景の塗りつぶし

    //テキスト表示
  tft.setRotation(3);                         //画面回転
  tft.setTextSize(3);                         //サイズ

  tft.setCursor(0, 10);                       //カーソル位置                      
  tft.setTextColor(ST77XX_GREEN);             //緑
  tft.printf("TAMANEGI\n");

  tft.setCursor(0, 50);                       //カーソル位置                      
  tft.setTextSize(2);                         //サイズ
  tft.setTextColor(ST77XX_RED);               //赤
  tft.printf("1.8inch LCD\n");
  tft.setTextColor(ST77XX_YELLOW);            //黄
  tft.printf("Res=128 x 160\n");
  tft.setTextColor(ST77XX_BLUE);              //青
  tft.printf("ST7735\n");
}

void loop()
{
}