技適付きESP32-CAM UnitCAMを試した

コンピュータ、組み込み

手軽に使用できるデジタルカメラUnitCAMを紹介します。
GPIOは少ないが、技適付きでカメラWebサーバーにできます。

紹介するもの

ESP32-CAM

特徴

小型の基板に、CAM(OVA-2640)を搭載したESP32基板。
技適付きESP32基板。

CPUESP32-WROOM-32E
Xtensa 32bit LX6 240MHz
フラッシュMemory4MB
GPIO3
ADC1
UART1 (1個スケッチ書き込み用)
I2C1
SPI1
その他OVA-2640 CAM
コネクタ GPIO 16, GPIO 17(UART2)
ピン配置
外観

使ってみて

GPIOピンはほとんどないので、Wifiを使ったWebCameraServerが適当な使い方と思います。
ESP32-WROOM32の技適対応CAMはあまり入手できませんが、UnitCAMはスイッチサイエンスなどでお手軽に入手できます。

その他のESP-CAM

準備

ライブラリ

ボードライブラリ

Arduino IDEのボードマネージャからESP32用のライブラリのインストールとボードの選択をします。

ボードマネージャのURLhttps://raw.githubusercontent.com/espressif/arduino-esp32/gh-pages/package_esp32_index.json
検索ESP
ボードライブラリesp32 by Espressif Systems バージョン x.x.x※
選択するボードツール > ボード > esp32 > ESP32 Dev Module
※ x.x.x Sep/2022 動作確認は2.0.5を使用しています

スケッチの書き込み

USB-シリアル変換アダプタ

電源とGND、TX,RXの配線をすることで書き込みができます。
UnitCAMにはUSBコネクタがないので、通常この書き込み方になります。

USB-シリアルのVCCからは5Vを供給します。
画像はFT232RL搭載TTL変換モジュールです。

UnitCAM配線USB-シリアル
5VVCC
GNDGND
GPIO1RX
GPIO3TX

画像はFT232RL搭載TTL変換モジュールです。
ジャンパピンによって5Vを選択しています。

スケッチの書き込みの時は、GPIO0とGNDをショートさせます(白のワイヤー)

基本スケッチ

カメラ webserver

説明

UnitCAMをwebserverにして映像配信します。

Wifiに接続するので、SSIDとパスワードを用意してスケッチに書き込みを行ってください。
スケッチを書き込みESP32-CAMを起動したら、シリアルモニタでIPを確認します。

ブラウザを起動し、IPを入力するとカメラの操作画面に切り替わります。
簡単な操作は結果にて紹介します。

スケッチ

Arduino サンプルスケッチの掲載です。
ファイル(F) > スケッチ例 > ESP32 > Camera > CameraWebServer

※サンプルに必要なファイルも出力されるので以下のサンプルスケッチをArduino IDEにコピペしただけでは動作しません。

スケッチ上部の、Select camera mode の#define定義個所を
#define CAMERA_MODEL_M5STACK_UNITCAM // No PSRAM のコメントを外し、
それ以外をすべてコメントにします。

36行目の const char* ssid = “*****” 箇所をWifiのSSIDに
37行目の const char* password = “*****” をWifiのパスワードに書き換えをします。

#include "esp_camera.h"
#include <WiFi.h>

//
// WARNING!!! PSRAM IC required for UXGA resolution and high JPEG quality
//            Ensure ESP32 Wrover Module or other board with PSRAM is selected
//            Partial images will be transmitted if image exceeds buffer size
//
//            You must select partition scheme from the board menu that has at least 3MB APP space.
//            Face Recognition is DISABLED for ESP32 and ESP32-S2, because it takes up from 15 
//            seconds to process single frame. Face Detection is ENABLED if PSRAM is enabled as well

// ===================
// Select camera model
// ===================
//#define CAMERA_MODEL_WROVER_KIT // Has PSRAM
//#define CAMERA_MODEL_ESP_EYE // Has PSRAM
//#define CAMERA_MODEL_ESP32S3_EYE // Has PSRAM
//#define CAMERA_MODEL_M5STACK_PSRAM // Has PSRAM
//#define CAMERA_MODEL_M5STACK_V2_PSRAM // M5Camera version B Has PSRAM
//#define CAMERA_MODEL_M5STACK_WIDE // Has PSRAM
//#define CAMERA_MODEL_M5STACK_ESP32CAM // No PSRAM
#define CAMERA_MODEL_M5STACK_UNITCAM // No PSRAM
//#define CAMERA_MODEL_AI_THINKER // Has PSRAM
//#define CAMERA_MODEL_TTGO_T_JOURNAL // No PSRAM
// ** Espressif Internal Boards **
//#define CAMERA_MODEL_ESP32_CAM_BOARD
//#define CAMERA_MODEL_ESP32S2_CAM_BOARD
//#define CAMERA_MODEL_ESP32S3_CAM_LCD

#include "camera_pins.h"

// ===========================
// Enter your WiFi credentials
// ===========================
const char* ssid = "********";
const char* password = "********";

void startCameraServer();

void setup() {
  delay(1000);
  Serial.begin(115200);
  Serial.setDebugOutput(true);

  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sscb_sda = SIOD_GPIO_NUM;
  config.pin_sscb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.frame_size = FRAMESIZE_UXGA;
  config.pixel_format = PIXFORMAT_JPEG; // for streaming
  //config.pixel_format = PIXFORMAT_RGB565; // for face detection/recognition
  config.grab_mode = CAMERA_GRAB_WHEN_EMPTY;
  config.fb_location = CAMERA_FB_IN_PSRAM;
  config.jpeg_quality = 12;
  config.fb_count = 1;
  
  // if PSRAM IC present, init with UXGA resolution and higher JPEG quality
  //                      for larger pre-allocated frame buffer.
  if(config.pixel_format == PIXFORMAT_JPEG){
    if(psramFound()){
      config.jpeg_quality = 10;
      config.fb_count = 2;
      config.grab_mode = CAMERA_GRAB_LATEST;
    } else {
      // Limit the frame size when PSRAM is not available
      config.frame_size = FRAMESIZE_SVGA;
      config.fb_location = CAMERA_FB_IN_DRAM;
    }
  } else {
    // Best option for face detection/recognition
    config.frame_size = FRAMESIZE_240X240;
#if CONFIG_IDF_TARGET_ESP32S3
    config.fb_count = 2;
#endif
  }

#if defined(CAMERA_MODEL_ESP_EYE)
  pinMode(13, INPUT_PULLUP);
  pinMode(14, INPUT_PULLUP);
#endif

  // camera init
  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK) {
    Serial.printf("Camera init failed with error 0x%x", err);
    return;
  }

  sensor_t * s = esp_camera_sensor_get();
  // initial sensors are flipped vertically and colors are a bit saturated
  if (s->id.PID == OV3660_PID) {
    s->set_vflip(s, 1); // flip it back
    s->set_brightness(s, 1); // up the brightness just a bit
    s->set_saturation(s, -2); // lower the saturation
  }
  // drop down frame size for higher initial frame rate
  if(config.pixel_format == PIXFORMAT_JPEG){
    s->set_framesize(s, FRAMESIZE_QVGA);
  }

#if defined(CAMERA_MODEL_M5STACK_WIDE) || defined(CAMERA_MODEL_M5STACK_ESP32CAM)
  s->set_vflip(s, 1);
  s->set_hmirror(s, 1);
#endif

#if defined(CAMERA_MODEL_ESP32S3_EYE)
  s->set_vflip(s, 1);
#endif

  WiFi.begin(ssid, password);
  WiFi.setSleep(false);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");

  startCameraServer();

  Serial.print("Camera Ready! Use 'http://");
  Serial.print(WiFi.localIP());
  Serial.println("' to connect");
}

void loop() {
  // Do nothing. Everything is done in another task by the web server
}
結果

UnitCAMを起動するとシリアルモニタに接続の様子と取得したIPアドレスが表示されます。

なぜか1行目は文字化けしやすいです。
… はWifiと接続中のようですが、電波が弱かったりすると接続できません。
表示されたIPアドレスをブラウザのURLに入力すると、カメラのWebサーバー画面が表示されます。

Get Still ボタンをおすことで撮影します。
画面左側の設定で画質やサイズを変更できます。
Start Streamボタンを押すことで動画配信ができます。

コメント

タイトルとURLをコピーしました