Arduino環境でSeeed XIAO RP2040を使う

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
XIAO2040

【スケッチの説明】
プルダウンしたピンの状態がHighならLEDを点灯、LowならLEDを消灯させます。

【ライブラリ】
Raspberry Pi Pico / RP2040 > Generic RP2040

【準備】
GPIO0(OUTPUT) -> 保護抵抗(200Ω) -> LED -> GND
3.3V -> タクトスイッチ -> GPIO1(INPUT_PULLDOWN)

【バージョン情報】
2023/1/29 : 新規
**********************************************************************/


#define LED 0        //基板実装LED
#define BUTTON 1     //タクトスイッチ

void setup()
{
  pinMode(LED, OUTPUT);               //ピン出力設定
  pinMode(BUTTON, INPUT_PULLDOWN);    //PULLDOWN設定
}

void loop()
{
  int iStat = digitalRead(BUTTON);    //LOW  = ボタン押下, HIGH = ボタン解放
  digitalWrite(LED, iStat);           //押下で点灯させたいので、反転させる
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
XIAO2040

【スケッチの説明】
PWM出力でのフェード点灯（ゆっくり点灯）とフェード消灯（ゆっくり消灯）を行います。

【ライブラリ】
Raspberry Pi Pico/RP2040 > Generic RP2040

【準備】
GPIO0(OUTPUT) -> 保護抵抗(200Ω) -> LED -> GND

【バージョン情報】
2023/1/29 : 新規
**********************************************************************/

#define PWM 0        //PWM 出力pin

void setup()
{
  pinMode(PWM , OUTPUT);
}

void loop()
{
  for(int i = 0; i < 256; i ++)
  {
    analogWrite(PWM, i);
    delay(2);
  }

  for(int i = 0; i < 256; i ++)
  {
    analogWrite(PWM, 255 - i);
    delay(2);
  }
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
XIAO2040

【スケッチの説明】
入力された電圧を読み取ります。

【ライブラリ】
 Raspberry Pi Pico/RP2040 > Generic RP2040

【準備】
XIAO2040 <-> LOLIN32 Lite
GPIO28(ADC)       <-> GPIO26(DAC)
GND               <-> GND

【バージョン情報】
2023/1/29 : 新規
**********************************************************************/

#define ADC 28

void setup()
{
  Serial.begin(115200);
  pinMode(ADC, INPUT);
}

void loop()
{
  int iADC = 0;

  //外部から入力された電圧を読み取り、結果をCOMに出力します。
  iADC = analogRead(ADC);
  Serial.printf("(ADC) = %d\r\n", iADC);
  delay(2);
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
XIAO2040

【スケッチの説明】
UART0 と COMの通信をします。

UART0から受信した内容をCOMへ送信します。
COMから受信した内容をUART0へ送信します。

【ライブラリ】
Raspberry Pi Pico/RP2040 > Generic RP2040


【準備】
UARTの送受信にFT232RLを使用します。

XIAO2040 <-> FT232RL
GPIO0 (UART0 TX) <-> RX
GP1O1 (UART0 RX) <-> TX

【バージョン情報】
2023/1/29 : 新規
**********************************************************************/

void setup()
{
  //Serial は USB(COM)を使ったシリアル通信用オブジェクト
  //Serial1は UART0の通信オブジェクト

  Serial1.setTX(0);            //UART0はSerial1オブジェクトを使用します。
  Serial1.setRX(1);             //デフォルトではTX = 0, RX = 1

  Serial.begin(115200);                //Serial1オブジェクトはCOM
  Serial1.begin(115200);               //SerialオブジェクトはUART0 
}

void loop()
{
  if(Serial.available() != 0)          //COMにデータがあれば、読み取った内容をUART0に送信
  {
      Serial1.write(Serial.read());
  }

  if(Serial1.available() != 0)         //UART0にデータがあれば、読み取った内容をCOMに送信
  {
      Serial.write(Serial1.read());
  }
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
XIAO 2040

【スケッチの説明】
SSD1306 OLEDの制御をします。
I2Cは I2C0とI2C1のどちらのサンプルも掲載しますが、
I2C0側はコメントアウトしますので、状況に応じてコメントを外してください。
※コメント検索 [I2C1の場合]

【ライブラリ】
Raspberry Pi Pico / RP2040 > Generic RP2040

【準備】
マイコン基板 <-> SSD1306
3V3           <-> VCC
GND           <-> GND
GP0(I2C0 SDA) <-> SDA
GP1(I2C0 SCL) <-> SCL

I2C1の場合
3V3           <-> VCC
GND           <-> GND
GP6(I2C1 SDA) <-> SDA
GP7(I2C1 SCL) <-> SCL

【バージョン情報】
2023/3/4 : 新規
2023/5/6 : コメント誤記修正。掲載サンプルはI2C1を使用します。I2C0はコメントアウトしています。
**********************************************************************/

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>


#define PIN0_SDA 0
#define PIN0_SCL 1
#define PIN1_SDA 6
#define PIN1_SCL 7

#define SCREEN_WIDTH 128                //解像度 128 x 64 で使用します。
#define SCREEN_HEIGHT 64                //SCREEN_HEIGHTは 32 に設定することができます。

#define OLED_RESET     -1               //使用しないので　-1を設定する。
#define SCREEN_ADDRESS 0x3C             //I2Cアドレスは 0x3C

//Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);     //I2C0の場合
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire1, OLED_RESET);     //I2C1の場合

void setup()
{
  
  // //I2C0の場合
  // Wire.setSDA(PIN0_SDA);            //Wire１ -> Wire
  // Wire.setSCL(PIN0_SCL);

  //I2C1の場合
  Wire1.setSDA(PIN1_SDA);
  Wire1.setSCL(PIN1_SCL);


  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    for(;;);
  }

  display.clearDisplay();               //何か表示されている場合に備えて表示クリア

  display.setTextSize(2);               //フォントサイズは2(番目に小さい)
  display.setTextColor(SSD1306_WHITE);  //色指定はできないが必要
  display.setCursor(20, 0);            //テキストの表示開始位置
  display.print(F("TAMANEGI"));         //表示文字列
  display.setCursor(15, 25);
  display.print(F("OLED 0.96"));
  display.setCursor(25, 45);
  display.print(F("SSD1306"));

  display.display();                    //バッファ転送（表示)
}

void loop()
{
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040搭載基板で利用できます。
XIAO RP2040

【スケッチの説明】
ST7735 LCDの制御をします。
SPIは SPI0とSPI1のどちらのサンプルも掲載しますが、
SPI1側はコメントアウトしますので、状況に応じてコメントを外してください。
※コメント検索 [SPI1の場合]

【ライブラリ】
Raspberry Pi Pico / RP2040 > Generic RP2040
Adafruit ST7735 and ST7789 Library
Adafruit GFX Library

【準備】
マイコン基板 <-> ST7735
3V3               <-> VCC
GND               <-> GND
GPIO26(SPI0 CS)   <-> CS
GPIO27            <-> Reset
GPIO28            <-> AO
GPIO3(SPI0 MOSI)  <-> SDA
GPIO2(SPI0 SCK)   <-> SCK

SPI1の場合
3V3               <-> VCC
GND               <-> GND
GPIO29(SPI1 CS)   <-> CS
GPIO6             <-> Reset
GPIO7             <-> AO
GPIO27(SPI1 MOSI) <-> SDA
GPIO26(SPI1 SCK)  <-> SCK

【バージョン情報】
2023/1/29 : 新規
2023/5/6  : SPI0使用するピン変更。SAMD21 XIAOと同配線にするため。
**********************************************************************/

#include <Adafruit_GFX.h> 
#include <Adafruit_ST7735.h>
#include <SPI.h>

//SPI0の場合
#define TFT_CS          26  // CS
#define TFT_RST         27  // Reset 
#define TFT_DC          28  // DC
#define TFT_MOSI        3   // MOSI
#define TFT_SCK         2   // SCK

//SPI1の場合
// #define TFT_CS          29  // CS
// #define TFT_RST         6   // Reset 
// #define TFT_DC          7   // DC
// #define TFT_MOSI        27  // MOSI
// #define TFT_SCK         26  // SCK

//SPI0の場合
Adafruit_ST7735 tft = Adafruit_ST7735(&SPI, TFT_CS, TFT_DC, TFT_RST);
//SPI1の場合
//Adafruit_ST7735 tft = Adafruit_ST7735(&SPI1, TFT_CS, TFT_DC, TFT_RST);

void setup(void) 
{
  //SPI0の場合
  SPI.setTX(TFT_MOSI);
  SPI.setSCK(TFT_SCK);

  //SPI1の場合
  // SPI1.setTX(TFT_MOSI);
  // SPI1.setSCK(TFT_SCK);
  

  tft.initR(INITR_BLACKTAB);                  //Init ST7735S初期化
  
  tft.fillScreen(ST77XX_BLACK);               //背景の塗りつぶし

   //テキスト表示
  tft.setRotation(3);                         //画面回転
  tft.setTextSize(3);                         //サイズ

  tft.setCursor(0, 10);                       //カーソル位置                      
  tft.setTextColor(ST77XX_GREEN);             //緑
  tft.printf("TAMANEGI\n");

  tft.setCursor(0, 50);                       //カーソル位置                      
  tft.setTextSize(2);                         //サイズ
  tft.setTextColor(ST77XX_RED);               //赤
  tft.printf("1.8inch LCD\n");
  tft.setTextColor(ST77XX_YELLOW);            //黄
  tft.printf("Res=128 x 160\n");
  tft.setTextColor(ST77XX_BLUE);              //青
  tft.printf("ST7735\n");
}

void loop()
{
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
XIAO RP2040

【スケッチの説明】
基板実装WS2812を点灯させます。
1秒間隔で、赤->緑->黄->青->紫->水->白　の順で点灯させます。

【ライブラリ】
Raspberry Pi Pico/RP2040 > Generic RP2040
Adafruit NeoPixel by Adafruit 1.10.6

【準備】
配線不要

【バージョン情報】
2023/5/6 : 新規
**********************************************************************/

#include <Adafruit_NeoPixel.h>

#define POWER_PIN 11          //NeoPixelの電源
#define DIN_PIN 12            // NeoPixel　の出力ピン番号
#define LED_COUNT 1           // LEDの連結数
#define WAIT_MS 1000          // 次の点灯までのウエイト
#define BRIGHTNESS 128        // 輝度
Adafruit_NeoPixel pixels(LED_COUNT, DIN_PIN, NEO_GRB + NEO_KHZ800);

void setup()
{
  //Neopixelの電源供給開始
  pinMode(POWER_PIN, OUTPUT);
  digitalWrite(POWER_PIN, HIGH);

  pixels.begin();             //NeoPixel制御開始
}

void loop()
{
  pixels.clear();
  
  //pixels.Color(Red, Green, Blue)で、パレット情報を作成する。
  //赤点灯
  pixels.setPixelColor(0, pixels.Color(BRIGHTNESS, 0, 0));
  pixels.show();
  delay(WAIT_MS);

  //緑点灯
  pixels.setPixelColor(0, pixels.Color(0, BRIGHTNESS, 0));
  pixels.show();
  delay(WAIT_MS);

  //赤　＋　緑　で　黄点灯
  pixels.setPixelColor(0, pixels.Color(BRIGHTNESS, BRIGHTNESS, 0));
  pixels.show();
  delay(WAIT_MS);

  //青点灯
  pixels.setPixelColor(0, pixels.Color(0, 0, BRIGHTNESS));
  pixels.show();
  delay(WAIT_MS);

  //赤　＋　青　で　紫点灯
  pixels.setPixelColor(0, pixels.Color(BRIGHTNESS, 0, BRIGHTNESS));
  pixels.show();
  delay(WAIT_MS);

  //緑　＋　青　で　水点灯
  pixels.setPixelColor(0, pixels.Color(0, BRIGHTNESS, BRIGHTNESS));
  pixels.show();
  delay(WAIT_MS);

  //赤　＋　緑　＋　青　で　白点灯
  pixels.setPixelColor(0, pixels.Color(BRIGHTNESS, BRIGHTNESS, BRIGHTNESS));
  pixels.show();
  delay(WAIT_MS);
}