I2CでOLEDモジュールの高速表示

//Programing by たまねぎ
//【スケッチの説明】
//RP2040 pico(以下 pico)で使用します。
//OLED画面に "TAMANEGI"と "YUMMI!!"を交互に表示させます。
//100回繰り返した時の時間を最後に表示します。
//
//【準備】
//・RP2040 pico側
//本スケッチでは SDA に GP0, SCL に GP1 を使用します。
//・SSD1306 OLED側
////I2Cアドレスは 0x3c 
//・配線
// RP2040 pico   SSD1306
// GP0           SDA
// GP1           SCL
// 3.3V          VCC
// GND           GND
//
//【バージョン情報】
// 2022/6/21 : 新規

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128                //解像度 128 x 64 で使用します。
#define SCREEN_HEIGHT 64                //SCREEN_HEIGHTは 32 に設定することができます。

#define OLED_RESET     -1               //使用しないので　-1を設定する。
#define SCREEN_ADDRESS 0x3C             //I2Cアドレスは 0x3C
Adafruit_SSD1306 display1(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);
Adafruit_SSD1306 display2(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);
                                        //表示制御にはAdafruit製 SSD1306を使用する。
                                        //初期化時には I2C0を使用する (Wire)
                                        
void setup() {
  
  Wire.setSDA(0);                       //I2C0で使用するGPは SDA = 0, SCL = 1
  Wire.setSCL(1);
  Wire.setClock(100000);		            //I2Cクロックはここで変更する。

  if(!display1.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    for(;;);
  }
  if(!display2.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    for(;;);
  }

  //このオブジェクトは "TAMANEGI" をバッファする
  display1.clearDisplay();
  display1.setTextSize(2);
  display1.setTextColor(SSD1306_WHITE);
  display1.setCursor(20, 20);
  display1.print(F("TAMANEGI"));
  
  //このオブジェクトは "YUMMY!!" をバッファする
  display2.clearDisplay();
  display2.setTextSize(2);
  display2.setTextColor(SSD1306_WHITE);
  display2.setCursor(30, 30);
  display2.print(F("YUMMY!!"));
  
  int Start_ms = millis();                //実行前の時間を記録

  //1000回交互に表示する
  for(int Count = 1; Count < 100; Count ++)
  {
    display1.display();                    //バッファ転送（表示)
    display2.display();
  }

  int Period_ms = millis() - Start_ms;    //終了時間を計測
  
  //計測時間を表示
  display1.clearDisplay();
  display1.setTextSize(1);
  display1.setTextColor(SSD1306_WHITE);
  display1.setCursor(10, 0);
  display1.printf("Measured time is");
  display1.setTextSize(2);
  display1.setCursor(30, 20);
  display1.printf("%d", Period_ms);
  display1.display();
  
}

void loop() {
}