SDカードリーダとLCD付いてデバッグプローブにもなる RP2040-GEEKを使ってみた

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040-GEEK

【スケッチの説明】
SPI1 を使用し、ST7789の表示を行います。

【ライブラリ】
Raspberry Pi Pico/RP2040 > Generic RP2040
Adafruit ST7735 and ST7789 Library
Adafruit GFX Library

【準備】
配線不要

【バージョン情報】
2023/9/21 : 新規
**********************************************************************/

#include <Adafruit_GFX.h> 
#include <Adafruit_ST7789.h>
#include <SPI.h>

#define TFT_CS    9
#define TFT_RST   12
#define TFT_DC    8
#define TFT_MOSI  11
#define TFT_SCK   10

Adafruit_ST7789 tft = Adafruit_ST7789(&SPI1, TFT_CS, TFT_DC, TFT_RST);

//S/W SPIはこちら。遅いが任意のピンを使用できる。
//Adafruit_ST7789 tft = Adafruit_ST7789(TFT_CS, TFT_DC, TFT_MOSI, TFT_SCK, TFT_RST);

void setup(void) 
{
  SPI1.setSCK(TFT_SCK);
  SPI1.setTX(TFT_MOSI);
  pinMode(25, OUTPUT);

  digitalWrite(25, HIGH);
  tft.init(135, 240);
  

  tft.fillScreen(ST77XX_BLACK);               //背景の塗りつぶし

  //テキスト表示
  tft.setRotation(3);                         //画面回転
  tft.setTextSize(4);                         //サイズ

  tft.setCursor(0, 0);                       //カーソル位置                      
  tft.setTextColor(ST77XX_GREEN);             //緑
  tft.printf("TAMANEGI\n");

  tft.setTextSize(3);                         //サイズ
  tft.setTextColor(ST77XX_RED);               //赤
  tft.printf("\n1.14inch LCD\n");
  tft.setTextColor(ST77XX_YELLOW);            //黄
  tft.printf("Res=135 x 240\n");
  tft.setTextColor(ST77XX_BLUE);              //青
  tft.printf("ST7789\n");
}

void loop()
{
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040-GEEK

【スケッチの説明】
SDカードモジュールからtest.jpgを読み出しST7789に表示します。

【ライブラリ】
Raspberry Pi Pico/RP2040 > Raspberry Pi Pico

Adafruit GFX Library
Adafruit ST7735 and ST7789 Library
TJpg_Decoder

【準備】
SDカードのルートフォルダに "tamanegi.jpg"を保存します。
jpgファイルのサイズは 135 x 240 サイズで保存します。

使用されているSPIは、TFTはSPI1, SDカードリーダはSPI0です。


【バージョン情報】
2023/9/23 : 新規
**********************************************************************/

#include <SPI.h>
#include <SD.h>

#include <TJpg_Decoder.h>
#include <Adafruit_ST7789.h>

#include <Adafruit_GFX.h>

//TFTピン設定
#define TFT_CS    9
#define TFT_RST   12
#define TFT_DC    8
#define TFT_MOSI  11
#define TFT_SCK   10

//SDピン設定
#define SD_CS     23  
#define SD_MISO   20
#define SD_MOSI   19
#define SD_SCK   18
#define FILENAME      "/tamanegi.jpg"

// JPGの最大サイズ(バッファを静的に確保するようにしているため、決め打ち。取り扱う最大ファイルサイズで変えるようにする)
#define JPG_SIZE_MAX (20 * 1024) //MAX 20KByteを想定

Adafruit_ST7789 tft = Adafruit_ST7789(&SPI1, TFT_CS, TFT_DC, TFT_RST);

struct jpg_file
{
  size_t size;
  uint8_t buf[JPG_SIZE_MAX];
};

jpg_file jpg;

//デコードを行うコールバック関数
bool tft_output(int16_t x, int16_t y, uint16_t w, uint16_t h, uint16_t *bitmap)
{
  if (y >= tft.height())
    return 0;

  tft.drawRGBBitmap(x, y, bitmap, w, h);

  return 1;
}

void setup()
{
  //SDカードにはSPI0 を使用する
  SPI.setTX(SD_MOSI);
  SPI.setRX(SD_MISO);
  SPI.setSCK(SD_SCK);

  //TFTにはSPI1を使用する
  SPI1.setTX(TFT_MOSI);
  SPI1.setSCK(TFT_SCK);

  //TFTの初期化と初期設定
  tft.init(135, 240);   
  tft.fillScreen(ST77XX_BLACK);               //背景の塗りつぶし
  tft.setRotation(3);

  Serial.begin(115200);
  //while(!Serial);
  delay(1000);
  
  //SDカードリーダの初期化とファイルの読み取り
  if (!SD.begin(SD_CS, SD_SCK_MHZ(16)))
  {
    Serial.println("SD initialization failed!");
    while(1);
  }

  TJpgDec.setCallback(tft_output);

  File jpgFile = SD.open(FILENAME, FILE_READ);
  if (!jpgFile)
  {
    Serial.printf("Open file failed [%s]\r\n", FILENAME);
    while(1);
  }

  jpg.size = jpgFile.size();

  if(sizeof(jpg.buf) < jpg.size) 
  {
    Serial.println("File size over");
    return;
  }

  //ファイル情報の表示
  uint16_t w = 0, h = 0;
  Serial.printf("file size = %d bytes\r\n", jpgFile.readBytes((char *)jpg.buf, jpg.size));
  TJpgDec.getJpgSize(&w, &h, jpg.buf, jpg.size);
  Serial.printf("Width = %d, height = %d\r\n", w, h);

  TJpgDec.setJpgScale(1);
  TJpgDec.drawJpg(0, 0, jpg.buf, jpg.size);             //画像の表示

  jpgFile.close();
}

void loop()
{
}