LAN付きRaspberry Pi Pico W5100S-EVB-Pico

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
全般で使用できます。
スケッチのLEDは基板実装ですが、ワイヤと抵抗とLEDの組み合わせで点灯します。

【スケッチの説明】
プルダウンしたピンの状態がHighならLEDを点灯、LowならLEDを消灯させます。

【ライブラリ】

【準備】
LEDピン -> 保護抵抗(約200Ω) -> LED Anode, LED Cathode -> GND
3.3V -> ボタンピン

【バージョン情報】
2022/10/28 : 新規
**********************************************************************/
//W5100S-EVB-Pico

#define LED 25       //基板実装LED
#define BUTTON 28    //タクトスイッチ

void setup()
{
  pinMode(LED, OUTPUT);               //ピン出力設定
  pinMode(BUTTON, INPUT_PULLDOWN);    //プルダウンで入力
}

void loop()
{
  int iStat = digitalRead(BUTTON);
  digitalWrite(LED, iStat);           //ボタンの状態をLEDに出力
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
Arduino開発環境対応基板全般使用できます。

例 : Raspberry Pi Pico

【スケッチの説明】
PWM出力でのフェード点灯（ゆっくり点灯）とフェード消灯（ゆっくり消灯）を行います。

【ライブラリ】

例  Raspberry Pi Pico/RP2040 > Raspberry Pi Pico

【準備】
指定ピン - 保護抵抗(約200Ω) - LED Anode, LED Cathode - GND
抵抗値は使用するLEDにより適切な抵抗値を求めてください。

【バージョン情報】
2022/10/28 : 新規
**********************************************************************/
//W5100S-EVB-Pico

#define PWM 25        //PWM 出力は 25th pin

void setup()
{
  pinMode(PWM , OUTPUT);
}

void loop()
{
  for(int i = 0; i < 256; i ++)
  {
    analogWrite(PWM, i);
    delay(2);
  }

  for(int i = 0; i < 256; i ++)
  {
    analogWrite(PWM, 255 - i);
    delay(2);
  }
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040搭載基板で使用できます。

例 : Raspberry Pi Pico

【スケッチの説明】
ADCへの入力AD値を読み取ります。

Raspberry Pi Pico の3.3Vを可変抵抗モジュールに通します。
可変抵抗モジュールからの電圧をRaspberry Pi Picoの指定ピンで読み出し、シリアル出力(COM)します。

【ライブラリ】

例  Raspberry Pi Pico/RP2040 > Raspberry Pi Pico

【準備】
Raspberry Pi Pico <-> スライド抵抗
3V3 <-> スライド抵抗 + 
GND <-> スライド抵抗 -
指定ピン <-> スライド抵抗 s

【バージョン情報】
2022/10/28 : 新規
**********************************************************************/
//W5100S-EVB-Pico

#define PIN_ADC0 26     //ADC0

void setup()
{
  delay(1000);
  Serial.begin(115200);         //結果はCOMに出力

  pinMode(PIN_ADC0, INPUT);
}

void loop()
{
  long lADC0 = 0;

  lADC0 = analogRead(PIN_ADC0);

  Serial.printf("ADC0 = %4d\n", lADC0);
  delay(100); 
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040搭載基板で使用できます。

例 : Raspberry Pi Pico

【スケッチの説明】
UART0 と UART1の通信をします。

UART0から受信した内容をUART1へ送信します。
UART1から受信した内容をUART0へ送信します。

【ライブラリ】

例  Raspberry Pi Pico/RP2040 > Raspberry Pi Pico

【準備】
UARTの送受信にFT232RLを使用します。
FT232RLはUART0用と、UART1用の2個使います。それぞれを(1), (2)と識別します。

Raspberry Pi Pico <-> FT232RL(1)
GP0 (UART0 TX) <-> RX
GP1 (UART0 RX) <-> TX

Raspberry Pi Pico <-> FT232RL(2)
GP4 (UART1 TX) <-> RX
GP5 (UART1 RX) <-> TX

【バージョン情報】
2022/10/31 : 新規
**********************************************************************/
//W5100S-EVB-Pico
//UART0 TX に設定可能なピン : 0, 12  (0は UART0 TXのデフォルト)
//UART0 RX に設定可能なピン : 1, 13  (1は UART0 RXのデフォルト)
//UART1 TX に設定可能なピン : 4, 8
//UART1 RX に設定可能なピン : 5, 9

void setup()
{
  //Serial は USB(COM)を使ったシリアル通信用オブジェクト
  //Serial1は UART0の通信用オブジェクト
  //Serial2は UART1の通信オブジェクト

  Serial1.setTX(0);            //UART0はSerial1オブジェクトを使用します。
  Serial1.setRX(1);             //デフォルトではTX = 0, RX = 1

  Serial2.setTX(4);
  Serial2.setRX(5);

  Serial1.begin(115200);                 //SerialオブジェクトはUART0 (COM)
  Serial2.begin(115200);                //Serial1オブジェクトはUART1
}

void loop()
{
  if(Serial2.available() != 0)          //UART1にデータがあれば、読み取った内容をUART0に送信
  {
      Serial1.write(Serial2.read());
  }

  if(Serial1.available() != 0)           //UART0にデータがあれば、読み取った内容をUART1に送信
  {
      Serial2.write(Serial1.read());
  }
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040搭載基板で利用できます。

例 : Raspberry Pi Pico

【スケッチの説明】
SSD1306 OLEDの制御をします。
I2Cは I2C0とI2C1のどちらのサンプルも掲載しますが、
I2C1側はコメントアウトしますので、状況に応じてコメントを外してください。
※コメント検索 [I2C1の場合]

【ライブラリ】
例 Raspberry Pi Pico / RP2040 > Raspberry Pi Pico

【準備】
マイコン基板 <-> SSD1306
3V3           <-> VCC
GND           <-> GND
GP0(I2C0 SDA) <-> SDA
GP1(I2C0 SCL) <-> SCL

I2C1の場合
3V3           <-> VCC
GND           <-> GND
GP2(I2C1 SDA) <-> SDA
GP3(I2C1 SCL) <-> SCL

【バージョン情報】
2022/10/30 : 新規
**********************************************************************/
//W5100S-EVB-Pico
//I2C0 SDA に設定可能なピン : 0, 4, 8, 12,
//I2C0 SCL に設定可能なピン : 1, 5, 9, 13,
//I2C1 SDA に設定可能なピン : 2, 6, 10, 14, (18), 26
//I2C1 SCL に設定可能なピン : 3, 7, 11, 15, (19), 27
//()内のピンは、LANを使わなければI2Cとして使用可能

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>


#define PIN0_SDA 0
#define PIN0_SCL 1
#define PIN1_SDA 2
#define PIN1_SCL 3

#define SCREEN_WIDTH 128                //解像度 128 x 64 で使用します。
#define SCREEN_HEIGHT 64                //SCREEN_HEIGHTは 32 に設定することができます。

#define OLED_RESET     -1               //使用しないので　-1を設定する。
#define SCREEN_ADDRESS 0x3C             //I2Cアドレスは 0x3C

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);     //I2C0の場合
//Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire1, OLED_RESET);     //I2C1の場合

                                        
void setup()
{
  
  // //I2C0の場合
  Wire.setSDA(PIN0_SDA);
  Wire.setSCL(PIN0_SCL);

  //I2C1の場合
  // Wire1.setSDA(PIN1_SDA);
  // Wire1.setSCL(PIN1_SCL);


  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    for(;;);
  }

  display.clearDisplay();               //何か表示されている場合に備えて表示クリア

  display.setTextSize(2);               //フォントサイズは2(番目に小さい)
  display.setTextColor(SSD1306_WHITE);  //色指定はできないが必要
  display.setCursor(20, 5);            //テキストの表示開始位置
  display.print(F("TAMANEGI"));         //表示文字列
  display.setCursor(35, 25);
  display.print(F("W5100s"));
  display.setCursor(20, 45);
  display.print(F("EVB-Pico"));

  display.display();                    //バッファ転送（表示)
}

void loop()
{
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040搭載基板で利用できます。

例 : Raspberry Pi Pico

【スケッチの説明】
ST7735 LCDの制御をします。
SPIは SPI0とSPI1のどちらのサンプルも掲載しますが、
SPI1側はコメントアウトしますので、状況に応じてコメントを外してください。
※コメント検索 [SPI1の場合]

【ライブラリ】
例 Raspberry Pi Pico / RP2040 > Raspberry Pi Pico

【準備】
マイコン基板 <-> ST7735
3V3               <-> VCC
GND               <-> GND
GPIO1(SPI0 CS)    <-> CS
GPIO28            <-> Reset
GPIO27            <-> AO
GPIO3(SPI0 MOSI)  <-> SDA
GPIO2(SPI0 SCK)   <-> SCK

SPI1の場合
3V3               <-> VCC
GND               <-> GND
GPIO13(SPI1 CS)   <-> CS
GPIO28            <-> Reset
GPIO27            <-> AO
GPIO14(SPI1 MOSI) <-> SDA
GPIO15(SPI1 SCK)  <-> SCK

【バージョン情報】
2022/10/30 : 新規
**********************************************************************/

#include <Adafruit_GFX.h> 
#include <Adafruit_ST7735.h>
#include <SPI.h>

//SPI0の場合
#define TFT_CS          1   // CS
#define TFT_RST         28  // Reset 
#define TFT_DC          27  // DC
#define TFT_MOSI        3   // MOSI
#define TFT_SCK         2   // SCK

//SPI1の場合
// #define TFT_CS          13  // CS
// #define TFT_RST         28  // Reset 
// #define TFT_DC          27  // DC
// #define TFT_MOSI        15  // MOSI
// #define TFT_SCK         14  // SCK

//SPI0の場合
Adafruit_ST7735 tft = Adafruit_ST7735(&SPI, TFT_CS, TFT_DC, TFT_RST);
//SPI1の場合
//Adafruit_ST7735 tft = Adafruit_ST7735(&SPI1, TFT_CS, TFT_DC, TFT_RST);

void setup(void) 
{
  //SPI0の場合
  SPI.setTX(TFT_MOSI);
  SPI.setSCK(TFT_SCK);

  //SPI1の場合
  // SPI1.setTX(TFT_MOSI);
  // SPI1.setSCK(TFT_SCK);
  

  tft.initR(INITR_BLACKTAB);                  //Init ST7735S初期化
  
  tft.fillScreen(ST77XX_BLACK);               //背景の塗りつぶし

  //テキスト表示
  tft.setRotation(3);                         //画面回転
  tft.setTextSize(3);                         //サイズ

  tft.setCursor(0, 20);                      //カーソル位置                      
  tft.setTextColor(ST77XX_RED);              //赤
  tft.printf("TAMANEGI\n");

  tft.setTextColor(ST77XX_GREEN);            //緑
  tft.printf("TAMANEGI\n");

  tft.setTextColor(ST77XX_BLUE);             //青
  tft.printf("TAMANEGI\n");

  tft.setTextColor(ST77XX_YELLOW);           //黄
  tft.printf("TAMANEGI\n");
}

void loop()
{
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

参考
Wiznet-Arduino Ethernetライブラリ
スケッチ例 > Ethernet > TelenetClient

【マイコン基板】
W5100S-EVB-Pico 基板で使用できます。

【スケッチの説明】
Telnet ClientとしてTelnet Serverと通信します。

COMから読み取った文字をServerへ送信します。
Serverから読みとった文字をCOMへ送信します。

【ライブラリ】
Raspberry Pi Pico/RP2040 > W5100S-EVB-Pico

【バージョン情報】
2022/10/28 : 新規
**********************************************************************/
//W5100S-EVB-Pico

#include <SPI.h>
#include <Ethernet.h>

//Mac アドレスと ローカルIPアドレスの設定
byte mac[] = {0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED};
IPAddress ip(192, 168, 1, 100);                       //たまねぎブログの紹介記事により TCP Client側は 192.168.1.100としています。

IPAddress server(192, 168, 1, 200);                   //接続先のサーバIP 
#define PORTNO 5000                                   //接続先サーバポート番号

EthernetClient client;

void setup() {
  Ethernet.init(17);                                  // WIZnet W5100S-EVB-Pico の CS

  Ethernet.begin(mac, ip);                            // Ethernet 接続開始

  Serial.begin(115200);
  while (!Serial) {
    ;
  }

  //Ethernetシールド確認
  if (Ethernet.hardwareStatus() == EthernetNoHardware) {
    Serial.println("Ethernet shield was not found.  Sorry, can't run without hardware. :(");
    while (true) {
      delay(1); // do nothing, no point running without Ethernet hardware
    }
  }

  //接続ができるまで待機
  while (Ethernet.linkStatus() == LinkOFF) {
    Serial.println("Ethernet cable is not connected.");
    delay(500);
  }

  delay(1000);
  Serial.println("connecting...");

  //サーバー側との接続
  if (client.connect(server, 5000)) {
    Serial.println("connected");
  } else {
    Serial.println("connection failed");
  }
}

void loop()
{

  //LANからの読み取りが可能であれば、読み取った結果をCOMで送信
  if (client.available() != 0)
  {
    char cClient = client.read();
    Serial.print(cClient);
  }

  //COMからの読み取りが可能であれば、読み取った結果をLANで送信
  while (Serial.available() > 0)
  {
    char cCOM = Serial.read();
    if (client.connected() == true)
    {
      client.print(cCOM);
    }
  }

  // サーバから切断された場合、ポーリング待機
  if (client.connected() == false) 
  {
    Serial.println();
    Serial.println("disconnecting.");
    client.stop();
    // do nothing:
    while (true)
    {
      delay(1);
    }
  }
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
W5100S-EVB-Pico 基板で使用できます。

例 : Raspberry Pi Pico

【スケッチの説明】
Telnet ClientとしてTelnet Serverと通信します。

COMから読み取った文字をClientへ送信します。
Clientから読みとった文字をCOMへ送信します。

【ライブラリ】
Raspberry Pi Pico/RP2040 > W5100S-EVB-Pico

【バージョン情報】
2022/10/28 : 新規
**********************************************************************/
//W5100S-EVB-Pico

#include <SPI.h>
#include <Ethernet.h>

#define SOCKET_PORT    5000             // 接続ポート

byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xEE
};

IPAddress ip(192, 168, 1, 200);
IPAddress myDns(192, 168, 1, 100);
IPAddress gateway(192, 168, 1, 100);
IPAddress subnet(255, 255, 255, 0);

EthernetServer server(SOCKET_PORT);

void setup()
{
  Ethernet.init(17);                            // WIZnet W5100S-EVB-Pico の CS

  // Ehternet 接続
  Ethernet.begin(mac, ip, myDns, gateway, subnet);

  Serial.begin(115200);
  
  if (Ethernet.hardwareStatus() == EthernetNoHardware) {
    Serial.println("Ethernet shield was not found.  Sorry, can't run without hardware. :(");
    while (true) {
      delay(1);
    }
  }

  Serial.println("ok....");
  Serial.print("localIP: ");
  Serial.println(Ethernet.localIP());
  Serial.print("subnetMask: ");
  Serial.println(Ethernet.subnetMask());
  Serial.print("gatewayIP: ");
  Serial.println(Ethernet.gatewayIP());
  Serial.print("dnsServerIP: ");
  Serial.println(Ethernet.dnsServerIP());

  server.begin();
  Serial.println("Server Start");
}

void loop()
{
  EthernetClient client = server.available();

   //LANからの読み取りが可能であれば、読み取った結果をCOMで送信
  if (client.available() != 0)
  {
    char cClient = client.read();
    Serial.print(cClient);
  }

  //COMからの読み取りが可能であれば、読み取った結果をLANで送信
  if(Serial.available() > 0)
  {
    char cCOM = Serial.read();
    server.print(cCOM);
  }

}