LCDモジュールを使う(ILI9341)

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040搭載基板で利用できます。

例 : Raspberry Pi Pico

【スケッチの説明】
ILI9341 LCDの制御をします。
SPIは SPI0とSPI1のどちらのサンプルも掲載しますが、
SPI1側はコメントアウトしますので、状況に応じてコメントを外してください。
※コメント検索 [SPI1の場合]

【ライブラリ】
例 Raspberry Pi Pico / RP2040 > Raspberry Pi Pico

【準備】
マイコン基板 <-> ILI9341
3.3V                  <-> VCC
GND                   <-> GND
GPIO17(SPI0 CS)       <-> TFT CS
GPIO22                <-> TFT Reset
GPIO28                <-> TFT AO(D/C)
GPIO19(SPI0 MOSI)     <-> TFT SDA
GPIO18(SPI0 SCK)      <-> TFT SCK
3.3V                  <-> LED

SPI1の場合
3V3               <-> VCC
GND               <-> GND
GPIO13(SPI1 CS)   <-> CS
GPIO28            <-> Reset
GPIO27            <-> AO
GPIO14(SPI1 MOSI) <-> SDA
GPIO15(SPI1 SCK)  <-> SCK

【バージョン情報】
2022/10/30 : 新規
2023/2/26 : SPI0 のピン番号変更。 他のLCDサンプルと共通番号にするため。
            サンプルで表示する文字列をLCD情報に変更。
**********************************************************************/

#include "Adafruit_GFX.h"
#include "Adafruit_ILI9341.h"
#include <SPI.h>

//SPI0の場合
#define TFT_CS          17   // CS
#define TFT_RST         22   // Reset 
#define TFT_DC          28   // D/C
#define TFT_MOSI        19   // SDI(MOSI)
#define TFT_SCK         18   // SCK

//SPI1の場合
// #define TFT_CS          13  // CS
// #define TFT_RST         28  // Reset 
// #define TFT_DC          27  // D/C
// #define TFT_MOSI        15  // SDI(MOSI)
// #define TFT_SCK         14  // SCK

//SPI0の場合
Adafruit_ILI9341 tft = Adafruit_ILI9341(&SPI, TFT_DC, TFT_CS, TFT_RST);

//SPI1の場合
//Adafruit_ILI9341 tft = Adafruit_ILI9341(&SPI1, TFT_DC, TFT_CS, TFT_RST);

//ソフトウエアSPIの場合
//Adafruit_ILI9341 tft = Adafruit_ILI9341(TFT_CS, TFT_DC, TFT_MOSI, TFT_SCK, TFT_RST, -1);


void setup(void) 
{
  //SPI0の場合
  SPI.setTX(TFT_MOSI);
  SPI.setSCK(TFT_SCK);

  //SPI1の場合
  // SPI1.setTX(TFT_MOSI);
  // SPI1.setSCK(TFT_SCK);
   tft.begin();
  
  tft.fillScreen(ILI9341_BLACK);               //背景の塗りつぶし

  //テキスト表示
  tft.setRotation(3);                         //画面回転
  tft.setTextSize(4);                         //サイズ

  tft.setCursor(0, 10);                       //カーソル位置                      
  tft.setTextColor(ILI9341_GREEN);             //緑
  tft.printf("TAMANEGI\n\n");

  tft.setTextSize(3);                         //サイズ
  tft.setTextColor(ILI9341_RED);               //赤
  tft.printf("2.4inch LCD\n");
  tft.setTextColor(ILI9341_YELLOW);            //黄
  tft.printf("Res=320 x 240\n");
  tft.setTextColor(ILI9341_BLUE);              //青
  tft.printf("ILI9341\n");
}

void loop()
{
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
ESP32 S3 BananaPi PicoW

【スケッチの説明】
ILI9341 LCDの制御をします。

【ライブラリ】
esp32 > ESP32S3 Dev Module

Adafruit GFX Library
Adafruit ILI9486

【準備】
Raspberry Pi Pico     <-> ILI9486
3.3V                  <-> VCC
GND                   <-> GND
GPIO2                 <-> TFT CS
GPIO7                 <-> TFT Reset
GPIO10                <-> TFT AO(D/C)
GPIO4                 <-> TFT SDA
GPIO3                 <-> TFT SCK
3.3V                  <-> LED

【バージョン情報】
2023/3/10 : 新規
**********************************************************************/
#include <SPI.h>
#include <ILI9486_SPI.h>
#include <Adafruit_GFX.h>

#define TFT_CS    2
#define TFT_RST   7
#define TFT_DC    10
#define TFT_MOSI  4
#define TFT_SCK   3

#include "Adafruit_GFX.h"
#include "Adafruit_ILI9341.h"
#include <SPI.h>

//SPI0の場合
Adafruit_ILI9341 tft = Adafruit_ILI9341(&SPI, TFT_DC, TFT_CS, TFT_RST);

//ソフトウエアSPIの場合
//Adafruit_ILI9341 tft = Adafruit_ILI9341(TFT_CS, TFT_DC, TFT_MOSI, TFT_SCK, TFT_RST, -1);

void setup(void) 
{
  //SPIピン設定
  SPI.begin(TFT_SCK, -1, TFT_MOSI, TFT_CS); 

  tft.begin();
  
  tft.fillScreen(ILI9341_BLACK);               //背景の塗りつぶし

  //テキスト表示
  tft.setRotation(3);                         //画面回転
  tft.setTextSize(4);                         //サイズ

  tft.setCursor(0, 10);                       //カーソル位置                      
  tft.setTextColor(ILI9341_GREEN);             //緑
  tft.printf("TAMANEGI\n\n");

  tft.setTextSize(3);                         //サイズ
  tft.setTextColor(ILI9341_RED);               //赤
  tft.printf("2.4inch LCD\n");
  tft.setTextColor(ILI9341_YELLOW);            //黄
  tft.printf("Res=320 x 240\n");
  tft.setTextColor(ILI9341_BLUE);              //青
  tft.printf("ILI9341\n");
}

void loop()
{
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
YD-RP2040

【スケッチの説明】
ILI9341 LCDのタッチ入力座標を表示します。

SPI0を使用します。
表示、タッチの入力ともにSPI0を使用します。
タッチのCSのみ個別にピンを選択してください。（SPI0用のピンでも構いません）

【ライブラリ】
 Raspberry Pi Pico / RP2040 > Generic RP2040

Adafruit GFX Libyrary
Adafruit ILI9341
XPT2046_Touchscreen

【準備】
マイコン基板 <-> ILI9341
3V3               <-> VCC
GND               <-> GND
GPIO17(SPI0 CS)   <-> CS
GPIO22            <-> Reset
GPIO28            <-> AO
GPIO19(SPI0 MOSI) <-> SDA
GPIO18(SPI0 SCK)  <-> SCK

GPIO20            <-> T_CS
GPIO16(SPI0 MISO) <-> T_OUT(MISO)
GPIO18(SPI0 SCK)  <-> T_CLK
GPIO19(SPI0 MOSI) <-> T_DIN(MOSI)

【バージョン情報】
2023/2/10 : 新規
2023/2/26 : SPI0 のピン番号変更。 他のLCDサンプルと共通番号にするため。
**********************************************************************/

#include <Adafruit_GFX.h>
#include <Adafruit_ILI9341.h>
#include <XPT2046_Touchscreen.h>
#include <SPI.h>


#define COMMON_SCK  18
#define COMMON_MOSI 19
#define COMMON_MISO 16

#define TOUCH_CS 20

#define TFT_DC  28
#define TFT_CS  17
#define TFT_RST 22

XPT2046_Touchscreen ts(TOUCH_CS);
Adafruit_ILI9341 tft = Adafruit_ILI9341(&SPI, TFT_DC, TFT_CS, TFT_RST);

void setup()
{
  Serial.begin(115200);

  //ESP SPI ピン設定
  SPI.setTX(COMMON_MOSI);
  SPI.setRX(COMMON_MISO);
  SPI.setSCK(COMMON_SCK);

  //表示開始
  tft.begin();
  tft.setRotation(1);
  tft.setTextSize(2);
  tft.fillScreen(ILI9341_BLACK);

  //タッチ入力開始
  ts.begin();
  ts.setRotation(3);

}

void loop()
{
  //タッチ状態読み取り
  boolean bTouch = ts.touched();
  //画面クリア
  tft.fillRect(0, 0, 640, 100, ILI9341_BLACK);

  //タッチがあればタッチされている座標の表示
  if (bTouch == true)
  {
   TS_Point tPoint = ts.getPoint();
    tft.setTextColor(ILI9341_WHITE);
    tft.setCursor(0, 0);
    tft.printf("(x,y) = (%d, %d)\r\n", tPoint.x, tPoint.y);
    Serial.printf("(x,y) = (%d, %d)\r\n", tPoint.x, tPoint.y);
  }
  else 
  {
    //タッチがなければタッチ無表示
    tft.setTextColor(ILI9341_RED);
    tft.setCursor(0, 0);
    tft.print("No Touch");
    
  }
  delay(100);
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
Raspberry Pi Pico

【スケッチの説明】
SDカードモジュールからtest.jpgを読み出しILI9341に表示します。

【ライブラリ】
Raspberry Pi Pico/RP2040 > Raspberry Pi Pico

Adafruit GFX Library
Adafruit ILI9341
TJpg_Decoder

【準備】
SDカードのルートフォルダに "test.jpg"を保存します。
jpgファイルのサイズは 320 x 240 サイズで保存します。

SPI0のMOSIとSCKは共通で使用します。
ILI9341に実装されているSDカードリーダ以外のモジュールを使用する場合、電源とGNDを配線します。

<<TFT側>>
Raspberry Pi Pico     <-> ILI9341
3.3V                  <-> VCC
GND                   <-> GND
GPIO17(SPI0 CS)       <-> TFT CS
GPIO22                <-> TFT Reset
GPIO28                <-> TFT AO(D/C)
GPIO19(SPI0 MOSI)     <-> TFT SDA
GPIO18(SPI0 SCK)      <-> TFT SCK
3.3V                  <-> LED

<<SDカードリーダ側>>
Raspberry Pi Pico     <-> TFカードリーダ
3.3V                  <-> VCC
GND                   <-> GND
GPIO21                <-> SD CS
GPIO19(SPI0 MOSI)     <-> SD MOSI
GPIO16(SPI0 MISO)     <-> SD MISO
GPIO18(SPI0 SCK)      <-> SD SCK

【バージョン情報】
2023/2/26 : 新規
**********************************************************************/

#include <SPI.h>
#include <SD.h>

#include <TJpg_Decoder.h>
#include <Adafruit_ILI9341.h>
#include <Adafruit_GFX.h>

//TFT SD共通ピン設定
#define COMMON_MOSI   19
#define COMMON_SCK    18

//TFTピン設定
#define TFT_CS        17
#define TFT_RST       22
#define TFT_DC        28

//SDピン設定
#define SD_CS         21  
#define SD_MISO       16
#define FILENAME      "/test.jpg"

#define BLACK   0x0000      //パレット 黒
#define WHITE   0xFFFF      //パレット 白

// JPGの最大サイズ(バッファを静的に確保するようにしているため、決め打ち。取り扱う最大ファイルサイズで変えるようにする)
#define JPG_SIZE_MAX (100 * 1024) //MAX 100KByteを想定

Adafruit_ILI9341 tft = Adafruit_ILI9341(&SPI, TFT_DC, TFT_CS, TFT_RST);

struct jpg_file
{
  size_t size;
  uint8_t buf[JPG_SIZE_MAX];
};

jpg_file jpg;

//デコードを行うコールバック関数
bool tft_output(int16_t x, int16_t y, uint16_t w, uint16_t h, uint16_t *bitmap)
{
  if (y >= tft.height())
    return 0;

  tft.drawRGBBitmap(x, y, bitmap, w, h);

  return 1;
}

void setup()
{
  //SPIピン設定
  SPI.setTX(COMMON_MOSI);
  SPI.setRX(SD_MISO);
  SPI.setSCK(COMMON_SCK);

  //TFTの初期化と初期設定
  tft.begin();                   //Init ILI9431初期化  
  tft.fillScreen(BLACK);        //背景の塗りつぶし
  tft.setRotation(3);

  Serial.begin(115200);
  //while(!Serial);
  delay(1000);
  
  //SDカードリーダの初期化とファイルの読み取り
  if (!SD.begin(SD_CS, SD_SCK_MHZ(8)))
  {
    Serial.println("SD initialization failed!");
    while(1);
  }

  TJpgDec.setCallback(tft_output);

  File jpgFile = SD.open(FILENAME, FILE_READ);
  if (!jpgFile)
  {
    Serial.printf("Open file failed [%s]\r\n", FILENAME);
    while(1);
  }

  jpg.size = jpgFile.size();

  if(sizeof(jpg.buf) < jpg.size) 
  {
    Serial.println("File size over");
    return;
  }

  //ファイル情報の表示
  uint16_t w = 0, h = 0;
  Serial.printf("file size = %d bytes\r\n", jpgFile.readBytes((char *)jpg.buf, jpg.size));
  TJpgDec.getJpgSize(&w, &h, jpg.buf, jpg.size);
  Serial.printf("Width = %d, height = %d\r\n", w, h);

  TJpgDec.setJpgScale(1);
  TJpgDec.drawJpg(0, 0, jpg.buf, jpg.size);             //画像の表示

  jpgFile.close();
}

void loop()
{
}