I2Cモジュールの作成（コントローラ)

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
RP2040-Zero

【スケッチの説明】
タクトボタンの入力状態を読み取ります。

ステップ１．
押下されたボタンの状態により、対応するビットをHIGHにする。
複数ボタンが押下されている場合は対応ビットのORとなる。

デバッグとして、押下状態はCOMに出力される。

ステップ２．(I2Cスレーブ側)
I2Cスレーブとして起動させる。(アドレスは 0x10固定)
マスターからの要求に対して、現在押下されているボタン情報を返答する。

ステップ３．(I2Cスレーブ側)

【ライブラリ】
Raspberry Pi Pico/RP2040 > Generic RP2040

【準備】
RP2040-Zero  <-> 接続先
GPIO27(INPUT)      <-> ボタン上
GPIO26(INPUT)      <-> ボタン下
GPIO15(INPUT)      <-> ボタン左
GPIO14(INPUT)      <-> ボタン右
GPIO8(INPUT)       <-> ボタン奥側
GPIO7(INPUT)       <-> ボタン手前側
GPIO6(INPUT)       <-> ボタン左側
GPIO5(INPUT)       <-> ボタン右側

5V出力モジュールは、マスター側のI2Cと接続するときにQwiicやGroveコネクタを使用できるようにするため。
コネクタへの入力電圧の3.3Vを5Vに変換してRP2040 Zeroを起動できる。

RP2040-Zero   <-> DCDC 5V出力モジュール
VIN(5V)           <-> VOUT
GND               <-> GND

RP2040-Zero   <-> JST SH 1mm 4pin
GPIO0(SDA)    <-> SDA
GPIO1(SCL)    <-> SCL

【バージョン情報】
2023/1/2 : 新規
**********************************************************************/

#include "Wire.h"

#define I2C_ADDR  0x10            //スレーブ側に指定するI2Cアドレス
#define I2C_SDA   0               //SDAにはGP0を使用する
#define I2C_SCL   1               //SCLにはGP1を使用する

//#define DEBUG

//I2Cマスターからのコマンドの要求による動作モード
enum eMode
{
  EM_Actual,                    //問い合わせがあったタイミングで押されている情報を返答する
  EM_Latch,                     //問い合わせがあるまでに押されているボタンのORを返答する
};

static short sGPIOTableSize = 0;        //ボタン配列数

static eMode lMode = EM_Actual;         //返答モード
static short sActual = 0x0000;          //問い合わせがあったタイミングで押されている情報を返答する
static short sLatch = 0x0000;           //問い合わせがあるまでに押されているボタンのORを返答する

//上、下、左、右、奥、手前、左ボタン、右ボタン
static const char cGPIOTable[] = {
  27, 26, 15, 14, 8, 7, 6, 5
};

//ボタン状態の確認順番配列と対応させることで、押下しているビットをHIGHにする。
//上、下、左、右、奥、手前、左ボタン、右ボタン
static const short sBitTable[] = {
  0x0010, 0x0020, 0x0040, 0x0080, 0x0001, 0x0002, 0x0004, 0x0008
};

static short Get_ButtonStat(void);        //ボタンの押下状態を読み取る。
static void onRequest();
static void onReceive(int len);
static void ExecuteCommand(char *Cmd);
static void Debug_DIN(void);


void setup()
{
#ifdef DEBUG
  Serial.begin(115200);
#endif

  sGPIOTableSize = sizeof(cGPIOTable);

  //GPIOの入力設定
  for(int i = 0; i < sGPIOTableSize; i ++)
  {
    pinMode(cGPIOTable[i], INPUT_PULLDOWN);
  }

  Wire.setSDA(I2C_SDA);             //通信に使用するI2Cアドレスピンを指定する
  Wire.setSCL(I2C_SCL);
  Wire.onReceive(onReceive);        //マスターからデータを受信したときに呼び出される関数の登録
  Wire.onRequest(onRequest);        //マスターからデータを要求されたときに呼び出される関数の登録
  Wire.begin(I2C_ADDR);             //通信開始

}

void loop()
{
  sActual = Get_ButtonStat();
  sLatch |= sActual;                //Latchの場合は、最新の情報のORを続ける。

//debugモード時はCOMにボタンの押下状態を出力
#ifdef DEBUG
  Serial.printf("Actual = %04x, Latch = %04x\r\n", sActual, sLatch);
  delay(2);
#endif

}

//現在のボタン押下状態を読み取る。
//戻り値 :
// ボタンの押下状態の組み合わせ
// bit下位から、上、下、左、右、奥、手前、左ボタン、右ボタン
static short Get_ButtonStat(void)
{
  short Ret = 0x0000;
  char cVal = 0;

  for(int i = 0; i < sGPIOTableSize; i ++)
  {
    cVal = digitalRead(cGPIOTable[i]);

    //読み取ったGPIO(n)の信号がHIGHなら、GPIO(n)に対するビットをHIGHにする。
    if(cVal == true){
      Ret |= sBitTable[i];
    } 
  }

  return Ret;

}

//マスターから要求があればモードの状態に応じて返答する。
static void onRequest()
{
  switch (lMode)
  {
    case EM_Actual:               //通常は現在の押下状態を返答する
      Wire.write(sActual);
      break;

    case EM_Latch:                //Latchモードの場合、一度返答したらActualモードに戻す
      Wire.write(sLatch);
      lMode = EM_Actual;
      sLatch = sActual;           //一度返答するとsLatchに現在の押下状態を保存する。
      break;
  }

}

//マスターからデータ送られてくると読み取りをする。
static void onReceive(int len)
{
  char cCommand[128];     //コマンドを一時的に保存するバッファ

  char cBuf = 0;
  long lCommandIndex = 0;

  while(Wire.available()){

    //マスターからの送信データがあれば読み取りを行う。
    //デリミタ(0x0d)を検出したらコマンドの実行
    //それ以外はコマンドバッファに積み上げる。
    cBuf = Wire.read();
    if(cBuf == 0x0d)
    {
      cCommand[lCommandIndex] = 0x00;
      ExecuteCommand(cCommand);         //マスターから読み取ったコマンドを実行する
    }
    else
    {
      cCommand[lCommandIndex] = cBuf;
      lCommandIndex ++;
    }
  }
}

static void ExecuteCommand(char *Cmd)
{
  String cBuf = Cmd;

#ifdef DEBUG
  Serial.printf("Command = %s\r\n", Cmd);
#endif

  //I2Cマスターからのコマンドを解析する
  //"LATCH"  前回のLATCHの返答から押下されたボタンのすべてのOR情報を次の返答にする
  if(cBuf.compareTo("LATCH") == 0)
  {
    lMode = EM_Latch;
  }
  //"LATCH"問い合わせ用の返答をクリア(現在の押下状態)にする
  else if(cBuf.compareTo("CLEAR") == 0)
  {
    sLatch = sActual;
  }

}

//デバッグ用の出力
//GPIO配列の入力状態をCOM出力する
static void Debug_DIN(void)
{
  long val;

  for(int i = 0; i < sGPIOTableSize; i ++)
  {
    val = digitalRead(cGPIOTable[i]);

    Serial.printf("[%2d] %4ld, ", cGPIOTable[i], val);
  }
  Serial.println("");

  delay(2);

}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
Sparkfun Pro Micro RP2040

【スケッチの説明】
I2C接続したI2C Controlerの状態を読み取ります。
1秒ごとに読み取りを行い、結果をCOMに出力します。

ステップ２．(I2Cマスター側)
I2Cスレーブとして起動させる。(アドレスは 0x10固定)
マスターからの要求に対して、現在押下されているボタン情報を返答する。

【ライブラリ】
Raspberry Pi Pico/RP2040 > SparkFun ProMicro RP2040

【準備】
Raspberry Pi Pico BOOT(マスター) <-> RP2040 Zero(スレーブ)
Qwiic <-> Qwiic(JST SH 1mm 4pin)

【バージョン情報】
2023/1/2 : 新規
**********************************************************************/

#include "Wire.h"

#define I2C_ADDR  0x10            //スレーブ側に指定するI2Cアドレス
#define I2C_SDA   16               //SDAにはGP0を使用する
#define I2C_SCL   17               //SCLにはGP1を使用する

void Debug_CommandTest(void);


uint32_t i = 0;

void setup() 
{

  Serial.begin(115200);           //パソコン側からの読み取りと書き込みに使用します。

  //I2Cマスター通信開始
  Wire.setSDA(I2C_SDA);           //I2Cアドレスピンを指定して通信開始
  Wire.setSCL(I2C_SCL);
  Wire.begin();
}

void loop() 
{
  char buf_com = 0;
  char buf_i2c = 0;

  Debug_CommandTest();

  //スレーブから現在のボタンの押下情報を読み取る
  if(Wire.requestFrom(I2C_ADDR, 2) != 0)
  {
    buf_i2c = Wire.read();
  }

  //スレーブから読み取ったデータをCOMへ送信する。
  if(Serial.availableForWrite())
  {
    Serial.printf("%04x \r\n", buf_i2c);
  }
}

//COMから入力した文字れにより、I2Cスレーブにコマンドを送信するテストコード
void Debug_CommandTest(void)
{
  delay(1000);            //ゆっくり動いてもらうためにウエイト
  char x;

  if(Serial.available() != 0)
  {
    x = Serial.read();
    if(x == 'L')
    {
      Wire.beginTransmission(I2C_ADDR);
      Wire.printf("LATCH\x0d");
      if(Wire.endTransmission(true) != 0)
      {
        Serial.println("送信エラー");
      }
    }
    else if(x == 'C')
    {    
      Wire.beginTransmission(I2C_ADDR);
      Wire.printf("CLEAR\x0d");
      if(Wire.endTransmission(true) != 0)
      {
        Serial.println("送信エラー");
      }
    }
  }

}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【マイコン基板】
Sparkfun Pro Micro RP2040

【スケッチの説明】
HID Mouseとして動作します。

I2C接続したI2C Controlerの状態を読み取り、ボタンの状態に応じマウスカーソルの操作をします。

【ライブラリ】
Raspberry Pi Pico/RP2040 > SparkFun ProMicro RP2040

【準備】
Raspberry Pi Pico BOOT(マスター) <-> RP2040 Zero(スレーブ)
Qwiic <-> Qwiic(JST SH 1mm 4pin)

【バージョン情報】
2023/1/24 : 新規
***********************************************************************/

#include <Mouse.h>
#include "Wire.h"

#define I2C_ADDR  0x10            //スレーブ側に指定するI2Cアドレス
#define I2C_SDA   16               //SDAにはGP0を使用する
#define I2C_SCL   17               //SCLにはGP1を使用する

//ボタン押下状態のビット情報
#define BUTTON_UP         0x10        //上
#define BUTTON_DOWN       0x20        //下
#define BUTTON_LEFT       0x40        //左
#define BUTTON_RIGHT      0x80        //右
#define BUTTON_WHEELUP    0x01        //ホイール上
#define BUTTON_WHEELDOWN  0x02        //ホイール下
#define BUTTON_CLICKLEFT  0x04        //クリック左
#define BUTTON_CLICKRIGHT 0x08        //クリック右


bool gbStatClickLeft = false;          //false = 解放状態, true = 押下状態
bool gbStatClickRight = false;         //false = 解放状態, true = 押下状態
long glWheelCount = 0;                  //ホイールの動作カウント

void setup()
{

  //I2Cマスター通信開始
  Wire.setSDA(I2C_SDA);           //I2Cアドレスピンを指定して通信開始
  Wire.setSCL(I2C_SCL);
  Wire.begin();
  
  Mouse.begin();

  Serial.begin(115200);
}

void loop() 
{
  const long lMoveVolume = 3;       //移動量

  long lVCount = 0;       //上下移動
  long lHCount = 0;       //左右移動
  long lWheelCount = 0;   //ホイール

  char cStat = 0;
  //I2C　コントローラから現在のボタン押下状態を読み取る
  if(Wire.requestFrom(I2C_ADDR, 2) != 0)
  {
    cStat = Wire.read();
  }
  Serial.printf("%02x\r\n",cStat);

  //<<カーソル移動箇所>>
  //カーソルの座標は画面の左上が原点(0,0)、上や左に移動するときはマイナス方向、下や右に移動するときはプラス方向
  //通常上下の同時押しや左右の同時押しはありえないので、それぞれに加減することで相殺する。
  if((cStat & BUTTON_UP) != 0) lVCount -= lMoveVolume;            //カーソル上移動（カーソル座標はマイナス方向)
  if((cStat & BUTTON_DOWN) != 0) lVCount += lMoveVolume;          //カーソルした移動 (カーソル座標はプラス方向)
  
  if((cStat & BUTTON_LEFT) != 0) lHCount -= lMoveVolume;          //カーソル左移動 (カーソル座標はマイナス方向)
  if((cStat & BUTTON_RIGHT) != 0) lHCount += lMoveVolume;         //カーソル右移動 (カーソル座標はプラス方向)
  Mouse.move(lHCount, lVCount, 0);


  //<<ホイール箇所>>
  if((cStat & BUTTON_WHEELUP) != 0) lWheelCount ++;                //ホイールプラス方向
  if((cStat & BUTTON_WHEELDOWN) != 0) lWheelCount --;              //ホイールマイナス方向
  if(lWheelCount != 0) Mouse.move(0,0, lWheelCount);

  //クリック箇所>>
  //左クリックボタンの押下/解放状態が変化したらマウスイベントを発生させる
  if((cStat & BUTTON_CLICKLEFT) != 0)
  {
      //false = 解放状態, true = 押下状態
      if(gbStatClickLeft == false)
      {
        //現在解放状態から押下状態に変化したら、クリックイベントの発生と状態の保存を行う
        Mouse.press(MOUSE_LEFT);
        gbStatClickLeft = true;
      }
  }
  else
  {
    //false = 解放状態, true = 押下状態
    if(gbStatClickLeft == true)
    {
      //現在解放状態から解放状態に変化したら、ボタンの解放イベントの発生と状態の保存を行う
      Mouse.release(MOUSE_LEFT);
      gbStatClickLeft = false;
    }
  }


  //左クリックボタンの押下/解放状態が変化したらマウスイベントを発生させる
  if((cStat & BUTTON_CLICKRIGHT) != 0)
  {
      //false = 解放状態, true = 押下状態
      if(gbStatClickRight == false)
      {
        //現在解放状態から押下状態に変化したら、クリックイベントの発生と状態の保存を行う
        Mouse.press(MOUSE_RIGHT);
        gbStatClickRight = true;
      }
  }
  else
  {
    //false = 解放状態, true = 押下状態
    if(gbStatClickRight == true)
    {
      //現在解放状態から解放状態に変化したら、ボタンの解放イベントの発生と状態の保存を行う
      Mouse.release(MOUSE_RIGHT);
      gbStatClickRight = false;
    }
  }
}