プラレールでGO!!

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【スケッチの説明】
NODE MCU ESP-32S 基板で使用できます。

Bluetooth通信の受信側として動作します。
Bluetoothの検索では "ESP32-Receiver" として表示されます。

モータドライバ md08a　の回転と速度の制御を行います。
Bluetooth送信側からモータの回転速度を受信します。
受信する値はアナログ(PWM)設定値で、0～255です。

シリアルでアスキーコードを受信するので、デリミタ[CR : 0x0d]を受け取ったら数値化して
PWMの設定値とします。


【ライブラリ】
esp32 > ESP32 Dev Module

【準備】
NODE MCU ESP32 - モータドライバ md08a
3.3V -> VCC, STBY
GND  -> GND
GP16 -> PWM(速度制御)
GP18 -> AIN1(回転方向1)
GP19 -> AIN2(回転方向2)

モータドライバ md08a - プラレール端子
AO1 -> どちらか
AO2 -> どちらか

モータドライバ md08a - バッテリー
VMOT -> +

【バージョン情報】
2022/8/10 : 新規
**********************************************************************/

#include "BluetoothSerial.h"

#define PIN_POTADC 28       //スライド抵抗からの電圧信号
#define PIN_PWM 16          //PWMによる回転速度制御
#define PIN_DIR1 18         //モータの回転方向1
#define PIN_DIR2 19         //モータの回転方向2

BluetoothSerial SerialBT;

void setup()
{
  SerialBT.begin("ESP32-Receiver");

  //各ピンの出力方向の設定
  pinMode(PIN_PWM,OUTPUT);      //回転速度と方向の出力
  pinMode(PIN_DIR1,OUTPUT);
  pinMode(PIN_DIR2,OUTPUT);

  analogWrite(PIN_PWM, 0);      //突然動くと危ないので出力は0
  
  //回転方向は固定。md08aのモータ出力をプラレールの端子につなぐと方向が決定するので、前進方向になるように現物合わせします。
  digitalWrite(PIN_DIR1, HIGH);
  digitalWrite(PIN_DIR2, LOW);

  Serial.begin(115200);
}

char RcvBuffer[8] = "";
char RcvIndex = 0;

void loop()
{
  char Rcv = 0;
  int pwm = 0;

  //Bluetooth受信があるか？
  if (SerialBT.available()) 
  {
    //受信があればバッファリング
    Rcv = SerialBT.read();
    RcvBuffer[RcvIndex] = Rcv;
    RcvIndex ++;
    
    //デリミタを検出したか？
    if(Rcv == 0x0d)
    {
      //デリミタをNULL文字にして、これまでに受信した文字列を数値化する。
      RcvBuffer[RcvIndex - 1] = 0x00;
      pwm = atoi(RcvBuffer);                        //受信文字列の検証はしたほうがいいが今回省略
      RcvIndex = 0;                                 //次の受信の準備

printf("pwm = %s, %d\n", RcvBuffer, pwm);           //デバッグ出力
      analogWrite(PIN_PWM, pwm);                    //PWM出力
    }
  }
}

/**********************************************************************
【ライセンスについて】
Copyright(c) 2022 by tamanegi
Released under the MIT license
'http://tamanegi.digick.jp/about-licence/

【スケッチの説明】
NODE MCU ESP-32S 基板で使用できます。

Bluetooth通信の送信側として動作します。
受信側のMACアドレスを調べてコンパイルしてください。

スライド抵抗値をアナログ出力出力範囲にリスケーリングして受信機側に送信します。
スライド抵抗 0Vにしたいので、読み取り最小値が0になるように誤差オフセット（ADOffset）を設定しています。

シリアル出力のデリミタはCR = 0x0dです。


【ライブラリ】
esp32 > ESP32 Dev Module

【準備】
NODE MCU ESP32 - スライド抵抗
3.3V -> +
GND  -> -
GP36 -> S

【バージョン情報】
2022/8/10 : 新規
**********************************************************************/
#include "BluetoothSerial.h"

#define PIN_POTADC 36       //スライド抵抗からの電圧信号

#define ADC_SIZE 4096       //ADCのサイズ(12bit)
#define PWM_SIZE 256        //PWMのサイズ(8bit)

BluetoothSerial SerialBT;
bool connected;

//uint8_t address[6]  = {0xAA, 0xBB, 0xCC, 0xDD, 0xEE, 0xFF};     //受信機側のMACアドレスを設定して、コメントを解除します。

void setup()
{
  pinMode(PIN_POTADC, INPUT);                       //スライド抵抗の読み取りを行う

  SerialBT.begin("PRTrain-Transmitter", true);      //Bluetooth開始

  connected = SerialBT.connect(address);

  //接続が成功するまで待機
  if(connected) {
Serial.println("Connect OK");
  } else {
    while(!SerialBT.connected(10000)) {
Serial.println("No connect"); 
    }
  }
  
  if (SerialBT.disconnect()) {
    Serial.println("Disconnected Succesfully!");
  }

  SerialBT.connect();
}
 
void loop()
{
  const int ADOffset = 500;                                     //スライド抵抗を最大にしたときに電圧が出ているとモータが止まらないので、停止させるためのオフセット

  int pot_adc = analogRead(PIN_POTADC) - ADOffset;
  if(pot_adc < 0) pot_adc = 0;

  int pwm = pot_adc / (ADC_SIZE / PWM_SIZE);                    //ADCの読み取り分解能12bit(4096)を、PWMの設定分解能8bit(256)へ変換する

  SerialBT.printf("%d\x0d", pwm);                               //Bluetooth出力　デリミタは CR = 0x0d
  
Serial.printf("pwm = %d\n", pwm);                               //デバッグ出力
  delay(10);
}